התאחדו והעירו: טבלאות פיין תומכות כעת בכותרות ובטיפים

כותרות ומיזוג תאים

כעת ניתן למזג מספר תאים בטבלה כדי ליצור כותרות ומפרידות מפוארות. עם זאת, תא ממוזג לא חייב להיות כותרת: אתה יכול
.למזג תאים בכל כיוון, כל עוד התא המתקבל אינו משפיע על תאים שכבר ממוזגים, ואינו יוצא מגבולות הטבלה

הכללים פשוטים. עליך להעביר את הקואורדינטות של table.merge_cells()‎ כדי ליצור תא ממוזג, השתמש בפונקציה החדשה
התא הראשון והאחרון שברצונך למזג. כל מה שביניהם ימוזג לתא אחד. גודל זה של תא ממוזג נקבע אוטומטית על פי מידות
.השורות והעמודות השכנות שלו

“SMA Table” בסקריפט לדוגמה למטה, אתה יכול לראות שלושה תאים ממוזגים: הראשון ממזג את כל התאים בשורה אפס ומכיל
.האחרים מתחתיו יוצרים את כותרות המשנה

//@version=5
indicator("MA Ratings", overlay = true)

TRANSP = 80
TABLE_WIDTH = 6
var CELL_TOOLTIP = "Cell color depends on the SMA direction: green for rising SMAs, red for falling ones"

var smaLengths = array.from(10, 20, 50, 100, 200, 500)

smaValues = array.new_float()
for i = 0 to array.size(smaLengths) - 1
    array.push(smaValues, ta.sma(close, array.get(smaLengths, i)))

var maTable = table.new(position.top_right, TABLE_WIDTH, 4, border_width = 2)

if barstate.isfirst
    headerColor = color.new(color.blue, TRANSP)
    table.cell(maTable, 0, 0, text = "SMA Table", bgcolor = headerColor)
    table.cell(maTable, 0, 1, text = "Short-term", bgcolor = headerColor)
    table.cell(maTable, 2, 1, text = "Long-term", bgcolor = headerColor)
    table.merge_cells(maTable, 0, 0, 5, 0)
    table.merge_cells(maTable, 0, 1, 1, 1)
    table.merge_cells(maTable, 2, 1, 5, 1)

if barstate.islast
    for i = 0 to TABLE_WIDTH - 1
        cellTitle = str.format("SMA {0}", array.get(smaLengths, i))
        cellValue = array.get(smaValues, i)
        cellColor = color.new(array.get(smaValues, i) >= array.get(smaValues[1], i) ? color.green : color.red, TRANSP)
        table.cell(maTable, i, 2, bgcolor = cellColor, text = cellTitle, text_color = color.gray, tooltip = CELL_TOOLTIP)
        table.cell(maTable, i, 3, bgcolor = cellColor, text = str.tostring(cellValue,  format.mintick), tooltip = CELL_TOOLTIP)

טיפים לכלים

השיפור השני לטבלאות הם עצות כלים. עצות כלים הן תוויות טקסט צפות המופיעות כאשר אתה מרחף מעל תא של טבלה
.משתמשים בהם כדי לספק מידע על תוכן התא מבלי להצטופף בטבלה

 ראה עצות table.cell() כדי ליצור תא עם תיאור כלים, פשוט העבירו מחרוזת לארגומנט תיאור הכלים החדש של הפונקציה
table.cell() בקריאה tooltip = CELL_TOOLTIP כלים בפעולה בסקריפט לדוגמה שלנו, שבו אנו משתמשים ב
:של שתי השורות האחרונות. עצות הכלים ייראו כך

כדי להישאר מעודכן לגבי תכונות חדשות של פיין, עקוב אחר הערות השחרור של מדריך למשתמש של פיין. חשבון
שלו בטלגרם, חשבון הטוויטר שלו ומהצ’אט הציבורי –Squawk Box משדר גם עדכונים מה PineCoders
.TradingView ב Pine Script

אנו מקווים שתמצא תכונה מבוקשת זו שימושית. אנא המשיכו לשלוח לנו משוב והצעות לשיפור. אנו בונים עבורך
.ותמיד נשמח לשמוע ממך TradingView