JustUncleL

Candlestick Trend Indicator v0.1 by JustUncleL

By request I am publishing these indicators+strategy suitable for longer term trades based on 1hr+ charts, consider it a beta version, but looks pretty good on paper.
This is a trend following indicators+strategy for Binary Options based on Candlestick patterns and trend line . It combines multiple indicators into a trend following strategies.
How to Use:
The indicator recognises and displays some useful candle patterns, when a candles pattern is highlighted it has already been tested as following the current trend direction that is indicated by the Zero Lag EMA(15) line, this also generates an alert condition for alarm setting.
The bet is confirmed entry via MACD DEUTER 2 colour(5,15,1), the MACD histogram being the same colour as hightlighted pattern bar - needs "MACD DEUTER 2 colour" indicator.
Second optional confirm is the drawn fractal upper/lower break lines, if the last fractal break line is also broken by a highlighted bar then this indicates a stronger trend confirmation.
Place Put/Call for 1-4 bar expiry.

Another trading technique for this set up: Ignore the candlestick patterns and just trade in the direction of the trendline/candle passing through the last Fractal support/resistance break level.

NOTE: This is a variation of the system originally designed for a forex trading system:
http://www.forexstrategiesresources.com/candlestick-forex-strategies/1-candlestick-trend/
Remove from Favorite Scripts Add to Favorite Scripts
//@version2
// Name: Candlestick Trend Indicator v0.1 by JustUncleL
// By: JustUncleL
// Date: 12-Aug-2016
// Version: v0.1
//
// Description:
//   This is a trend following indicator+stategy for Binary Options
//   based on Candlestick patterns and trend line - 
//   NOTE: original system was a forex trading system.
//   This code combines a number of indicators to create an overall
//   trading strategy.
//   The indicator recognises and displays some useful candle patterns.
//   The highlighted candles are the patterns that are following the current 
//   trend direction that is indicated by the Zero Lag EMA(15) line,
//   this also generates an alert condition for alarm setting.
//   The fractal upper/lower break lines are also draw, if the last
//   fractal break line is broken by a highlighted bar then this
//   indicates a stronger trend conformation.
//   Confirm entry via MACD DEUTER 2 colour(5,15,1), the MACD histogram
//   same colour as hightlighted bar - needs "MACD DEUTER 2 colour" indicator.
//
//   This multi-indicator set up is suitable for 1hr, 4hr and daily charts 
//   with 1-4 candle expiry.
//   
// references:
//   - [RS]Fractal Levels  by RicardoSantos
//   - Almost Zero Lag EMA [LazyBear]
//   - Candlestick Patterns With EMA by rmwaddelljr
//   - http://www.forexstrategiesresources.com/candlestick-forex-strategies/1-candlestick-trend/
//
// Modifications:
//  0.1 - original.
//
study(title="Candlestick Trend Indicator v0.1 by JustUncleL", shorttitle="CDLTRD v0.1 by JustUncleL", overlay=true, scale=scale.right)
//
// this section based on Almost Zero Lag EMA [LazyBear]
length = input(15,minval=2,title="Length ZeroLagEMA")
src=close
ema1=ema(src, length)
ema2=ema(ema1, length)
d=ema1-ema2
zlema=ema1+d
col =  zlema > zlema[1] ? green : red
up = zlema > zlema[1] ? 1 : 0
down = zlema < zlema[1] ? 1 : 0
plot(zlema,color=col, style=line, linewidth=4, transp=0)

// Find all Fractals.
// This section based on [RS]Fractal Levels  by RicardoSantos
hidefractals = input(false)
hidelevels = input(false)
topfractal = high[2] > high[1] and high[2] > high and high[2] > high[3] and high[2] > high[4]
botfractal = low[2] < low[1] and low[2] < low and low[2] < low[3] and low[2] < low[4]

plotshape(hidefractals ? na : topfractal, color=green, transp=0, style=shape.triangleup, location=location.abovebar, offset=-2, size=size.tiny)
plotshape(hidefractals ? na : botfractal, color=red, transp=0, style=shape.triangledown, location=location.belowbar, offset=-2, size=size.tiny)

topfractals = topfractal ? high[2] : topfractals[1]
botfractals = botfractal ? low[2] : botfractals[1]

topfcolor = topfractals != topfractals[1] ? na : green
botfcolor = botfractals != botfractals[1] ? na : red

plot(hidelevels ? na : topfractals, color=topfcolor, transp=0, linewidth=2)
plot(hidelevels ? na : botfractals, color=botfcolor, transp=0, linewidth=2)

//
// This section based on Candlestick Patterns With EMA by rmwaddelljr
hhb = input(false, title="Hide Highlight Trendline Bars")

ms = (close[2] < open[2] and max(open[1], close[1]) < close[2] and open > max(open[1], close[1]) and close > open )
plotshape(ms,  title= "Morning Star", location=location.belowbar, color=green, style=shape.arrowup, offset=-1, text="Morn\nStar")

ss = (open[1] < close[1] and open > close and high - max(open, close) >= abs(open - close) * 3 and min(close, open) - low <= abs(open - close))
plotshape(ss, title= "Shooting Star", location=location.belowbar, color=green, style=shape.arrowup, text= "Shoot\nStar")

beh = (close[1] > open[1] and open > close and open <= close[1] and open[1] <= close and open - close < close[1] - open[1] )
plotshape(beh, title= "Bearish Harami",  color=red, style=shape.arrowdown, text="Bear\nHarami")

blh = (open[1] > close[1] and close > open and close <= open[1] and close[1] <= open and close - open < open[1] - close[1] )
plotshape(blh,  title= "Bullish Harami", location=location.belowbar, color=green, style=shape.arrowup, text="Bull\nHarami")

bee = (close[1] > open[1] and open > close and open >= close[1] and open[1] >= close and open - close > close[1] - open[1] )
//bee = (close[1] > open[1] and open > close and open - close > close[1] - open[1] )
plotshape(bee,  title= "Bearish Engulfing", color=red, style=shape.arrowdown, text="Bearish\nEngulf")

ble = (open[1] > close[1] and close > open and close >= open[1] and close[1] >= open and close - open > open[1] - close[1] )
//ble = (open[1] > close[1] and close > open and close - open > open[1] - close[1] )
plotshape(ble, title= "Bullish Engulfing", location=location.belowbar, color=green, style=shape.arrowup, text="Bullish\nEngulf")

upper = highest(10)[1]
ps = (close[1] < open[1] and  open < low[1] and close > close[1] + ((open[1] - close[1])/2) and close < open[1])
plotshape(ps, title= "Piercing Line", location=location.belowbar, color=green, style=shape.arrowup, text="Pierc\nSig")

blk = (open[1]>close[1] and open>=open[1] and close>open)
plotshape(blk, title= "Bullish Kicker", location=location.belowbar, color=green, style=shape.arrowup, text="Bull\nKick")

bek = (open[1]<close[1] and open<=open[1] and close<=open)
plotshape(bek, title= "Bearish Kicker", color=red, style=shape.arrowdown, text="Bear\nKick")

//
aboveTLine = up and not hhb
belowTLine = down and not hhb
//
barcolor(ms and belowTLine ? lime : na)  
barcolor(ss and belowTLine ? lime : na)  
barcolor(bek and belowTLine ? fuchsia : na)
barcolor(beh and belowTLine ? maroon : na)
barcolor(bee and belowTLine ? maroon : na)
barcolor(ps and aboveTLine ? lime : na)
barcolor(blk and aboveTLine ? yellow : na)
barcolor(ble and aboveTLine ? lime : na)
barcolor(blh and aboveTLine ? lime : na)

//
barAlert = ((ms or ss or bek or bee or beh) and belowTLine) or ((ps or blk or ble or blh) and aboveTLine)
alertcondition(barAlert,title="CDLTRD Alert", message="CDLTRD Bar Alert")
//EOF
JustUncleL
mo_trade
6 months ago
Hi. Can i use this on short term binary option trading like 1 min or 5 min? Thanks
Reply
JustUncleL PRO mo_trade
6 months ago
I have found that candlestick patterns are not very reliable at less than 1hr, I would not recommend even trying at 1min or 5min. I have not done any testing for less than 1hr charts, but you could try at 15min in demo and use the optional Fractal confirmation to help, it may work?
Reply
mo_trade JustUncleL
5 months ago
Alright. thank you so much.
Reply
benedictwellstood
6 months ago
I love you're work, really. Thank you. Fascinating.
Reply
JustUncleL PRO benedictwellstood
6 months ago
Thank you, I have actually been using this system on my own live trading over the last few days, assessing each alert on its merits and have been quite successful. However, I think it can be improved particularly reviewing what candle patterns are used. I have quite a collection of systems and chart set ups accumulated over time (looking for one that suits the way I want to trade) and I will release some more of the better ones as I add documentation and review them again.
Reply
raoadnan84
6 months ago
Hi, Looks good, i am try this one as you recommend on H1,H4 higher chart. Thanks, appreciate your efforts.
Reply
NicholasB
5 months ago
Hello JustUnclel, hope you're well, how do I use the code in this page , am confused.
Any help will be highly appreciate. Thanks
Reply
JustUncleL PRO NicholasB
5 months ago
This is quite a complex chart with lots of information on it. It takes time to get to use it properly, as the Alerts are not signals, they are potential good trading positions which need further analysis to get the best trades.
Reply
NicholasB JustUncleL
5 months ago
thanks, testing it already, feeling it will be useful.
Reply
quickturtle
2 months ago
Nice....can't wait to see your other stuff you mentioned you will be coming out with....thanks
Reply
JustUncleL PRO quickturtle
2 months ago
@quickturtle, Please note that this is indicator has been updated and the latest is revision v0.5
Reply
ElderFx JustUncleL
2 months ago
@JustUncleL, how do i get it
Reply
JustUncleL PRO ElderFx
2 months ago
@ElderFx, Search in the indicator library or through my published scripts.
Reply
Ideas Scripts Chart
United States
United Kingdom
India
España
Italia
Brasil
Россия
Türkiye
日本
한국
Home Stock Screener Economic Calendar How It Works Chart Features House Rules Moderators For the WEB Widgets Stock Charting Library Priority Support Feature Request Blog & News FAQ Help & Wiki Twitter
Private Messages Chat Ideas Published Followers Following Priority Support Public Profile Profile Settings Account and Billing Sign Out