JustUncleL

Price Action Trading System v0.2 by JustUncleL

This implementation is a variation of 'Price Action Channel, “The Gold             line” Trading System' designed for Binary Options, originally a scalping system, but without the MA cross "Arrow1" and "Chandelier Stop" indicators.
This is suitable for 15min charts, for 2 to 4 candles (30min to 60min) expiry.
Remove from Favorite Scripts Add to Favorite Scripts
//@version=2 
//Name: Price Action Channel Trading System v0.2 by JustUncleL
//Created By: JustUncleL on 3 Aug 2016
//Version: 0.2
//
//Description: 
//  This is an implementation of 'Price Action Channel, “The Gold line” Trading System'
//  for Binary Options, originally a scapling system, but without the MA cross "Arrow1".
//  This is a Trend following price action system.
//  To complete the setup instead of the two "Chandelier Stop" indications, 
//  I replaced them with a MACD(12,17,8) indicator.
//  This is suitable for 15min charts, with 2 to 4 candle (30min to 60min) expiry.
//
//  Call Entry:
//  - Green Triangle, confirmed by MACD background green.
//  - CCI Candles aqua.
//  - For best call entry wait for the price retrace back to the gold line, 
//    back inside channel also works well.
//
//  Put Entry:
//  - Red Triangle, confirmed by MACD background red.
//  - CCI Candles black.
//  - For best put entry wait for the price retrace on the gold line,
//    back inside channel also works well.
//
//Notes:
//  - will work well on trending patterns only.
//  - works best on the first alert after MACD cross over.
//  - don't take trades when MACD and signal are close together.
//
//Modifications:
//  0.2 : Use MACD instead of Chandelier Stop for filtering, giving
//        a simplier looking chart.
//  0.1 : Original version.
//
// reference:
//  - Chandelier Stop by pipCharlie (not used in this version)
//  - http://www.forexstrategiesresources.com/scalping-forex-strategies/73-price-action-channel-the-gold-line/
//  - Used some ideas from RSI Candles by glaz
//
study(title="Price Action Trading System v0.2 by JustUncleL",overlay = true, shorttitle="CCIPAT v0.2 by JustUncleL")
//
len = input(14, minval=1, title="CCI Length")
lenUpper = input(75, minval=1, title="CCI UpLevel")
lenLower = input(-75, minval=1, title="CCI DownLevel")
bars_on = input(true, title="Color CCI Bars")
src = input(close,title="CCI Source") 
lenLo   = input(5, minval=2, title="Low Channel Length")
lenHi   = input(5, minval=2, title="High Channel Length")
lenMe = input(4, minval=1, title="Median Channel Length")
//
fastLength = input(12, minval=1,title="MACD Fast Length")
slowLength=input(17,minval=1,title="MACD Slow Length")
signalLength=input(8,minval=1,title="MACD Signal Length")
//
// Calculate MACD and color background
fastMC = ema(src, fastLength)
slowMC = ema(src, slowLength)
macd = fastMC - slowMC
signal = sma(macd, signalLength)
OutputSignal = signal > macd ? 1 : signal < macd ? -1 : 0
bgcolor(OutputSignal>0?red: OutputSignal<0?green:yellow, transp=90)

// Calculate and draw the Price Action channel 
emaLo = ema(low,lenLo)
emaHi = ema(high,lenHi)
emaMe = ema(hl2,lenMe)
plot(emaLo,title="Low Price Line",style=line,color=gray,transp=0,linewidth=2)
plot(emaHi,title="High Price Line",style=line,color=gray,transp=0,linewidth=2)
plot(emaMe,title="Median Price Line",style=line,color=orange,transp=0,linewidth=2)

// Calculate CCI
cciVal = cci(src, len)

// Calculate CCI indicating continuance of trend.
isup = cciVal > lenUpper
isdown = cciVal < lenLower
barcolor(bars_on ? isup ? aqua : isdown ? black : na : na )

// Check have alert and use MACD filter
cciup_alert = isup and OutputSignal<0? na(cciup_alert[1]) ? 1 : cciup_alert[1]+1 : 0
ccidn_alert = isdown and OutputSignal>0? na(ccidn_alert[1]) ? 1 : ccidn_alert[1]+1 : 0

plotshape(cciup_alert==1? cciup_alert : na, title="CCIPAT Up Arrow", style=shape.triangleup,location=location.belowbar, color=olive, transp=0, size=size.small)
plotshape(ccidn_alert==1? ccidn_alert : na, title="CCIPAT Down Arrow", style=shape.triangledown,location=location.abovebar, color=red, transp=0, size=size.small)

// generate an alert if required.
alertcondition(cciup_alert==1 or ccidn_alert==1, title="CCIPAT Alert", message="CCIPAT Alert")

//EOF
bondlink
4 months ago
Thanks for the effort --this looks interesting. Now, what is the win rate for this strategy (after how many trades)....that is if you tested it on real live trading?
Reply
JustUncleL PRO bondlink
4 months ago
Thank you for interest. I have not extensively tested the performance, however, this is showing very good ITM rates at over 70% in live testing for me. I don't trade every alert, the alerts are indicators of a possible good trading position, you need to follow good trading guidelines and access each alert on its own merits. Always practise any new strategy in a Demo account for a few weeks to become familiar with the best trade setups and access it's performance.
Reply
bondlink JustUncleL
4 months ago
Thanks. I will test it on demo and share my results with you.
Reply
bondlink JustUncleL
4 months ago
Do you have a compiled version of this that can work with MT4 or MT5?
Reply
JustUncleL PRO bondlink
4 months ago
If you follow the webpage reference in my script header comments there you find the MT4 code freely available and full description for the original setup.
Reply
rsigna JustUncleL
4 months ago
Hey, where's the webpage reference?
Reply
JustUncleL PRO rsigna
4 months ago
It is in the description comments of the script, but repeat it:
http://www.forexstrategiesresources.com/scalping-forex-strategies/73-price-action-channel-the-gold-line/
Reply
gianfranco60
4 months ago
It is really a good work. I am using it like a trade system with two indicator rsi 7 gg and CM LW volatility
Reply
JustUncleL PRO gianfranco60
4 months ago
Thank you, I'm glade you like it, I think it is one my strongest indicators that I use. I have a similar unreleased indicator that uses RSI instead of CCI for triggers, so adding RSI confirms should complement the strategy. I am not familiar with CM LW volatility and cannot find it in the public scripts. Normally I have only used this indicator without any other confirms, but adding RSI(7) looks like a good extra confirm filter.
Reply
gianfranco60 JustUncleL
4 months ago
I was wrong I mean CMoody L Williams VIX
Reply
JustUncleL PRO gianfranco60
4 months ago
Okay thanks, yes I know VIX series of indicators by CM, I have used them before. By the way I have just released an updated version of this alert/indicator that includes your suggested RSI filter and also a market direction Filter, also you can turn the filters on and off to see the effects on alert triggers. (I should have the thumbnail picture fixed now)
Reply
Ideas Scripts Chart
United States
United Kingdom
India
España
Italia
Brasil
Россия
Türkiye
日本
한국
Home Stock Screener Economic Calendar How It Works Chart Features House Rules Moderators For the WEB Widgets Stock Charting Library Priority Support Feature Request Blog & News FAQ Help & Wiki Twitter
Private Messages Chat Ideas Published Followers Following Priority Support Public Profile Profile Settings Billing Sign Out