Potensi Baru dalam Bekerja dengan Warna pada Pine

Skrip Anda akan berkilau dengan warna-warna cerah setelah kami menambahkan warna dan gradien rangkaian baru dari palet RGB.

Sebuah fungsi baru ‘color.rgb (red, green, blue, transp)’ telah ditambahkan kedalam Pine. Ini memungkinkan anda untuk mengatur warna dengan menetapkan nilai dari komponen merah, hijau, biru dan transparansinya (transp) sebagai sebuah argumen. Anda kini dapat menyingkirkan definisi dari seluruh palet warna yang digunakan di dalam skrip dan mulai mengkalkulasikan warnanya berdasarkan argumen yang ditetapkan. Lihatlah contoh sederahan berikut ini, yang menunjukkan betapa mudahnya kini dalam menggunakan transisi warna yang kompleks:

//@version=4
study("Relative Bars Color Saturation", "RBCS", overlay=true)

i_barcolor = input(color.rgb(33, 150, 243), "Bar Color", input.color)

f_grad_transp(_c_col, _transp) =>
    _c_red = color.r(_c_col)
    _c_green = color.g(_c_col)
    _c_blue = color.b(_c_col)
    color.rgb(_c_red, _c_green, _c_blue, _transp)

f_indexedPercent(_currentValue, _relativeValue, _maxValue) =>
    _currentValue * _maxValue / _relativeValue

transp = f_indexedPercent(abs(close - open), high - low, 100)
c_color = f_grad_transp(i_barcolor, transp)
barcolor(c_color)

Nilai komponen warna ditetapkan dalam kisaran dari 0 (paling tidak intens) hingga 255 (paling intens). Untuk komponen transparansi, kisaran ini dari 0 (warna penuh) hingga 100 (benar-benar transparan).

Jika anda perlu memperoleh nilai numerik dari suatu warna atau komponen transparansi tertentu, cobalah fungsi spesial ‘color.r()’, ‘color.g()’, ‘color.b()’ dan ‘color.t()’ dengan menetapkan sebuah warna sebagai argumennya.

Dan fungsi ‘color.from_gradient()’ memungkinkan anda dalam membuat transisi warna yang mengesankan didalam setiap barnya, warna dari skripnya hanya dibatasi oleh imajinasi anda. Berikut adalah contoh yang menampilkan betapa mudahnya kini dalam menggambarkan warna tergantung pada nilai dari indeks kekuatan relatif/relative strength index:

//@version=4
study("RGB RSI")
i_src = input(close, "Source", input.source)
i_length = input(14, "Length", input.integer)

f_grad_transp(_c_col, _transp) =>
    _c_red = color.r(_c_col)
    _c_green = color.g(_c_col)
    _c_blue = color.b(_c_col)
    color.rgb(_c_red, _c_green, _c_blue, _transp)

rsi = rsi(i_src, i_length)
c_grad = color.from_gradient(rsi, 30, 70, color.lime, color.red)

plot(rsi, color=c_grad, linewidth=3)
band1 = hline(70, "Overbought", color=color.rgb(255, 82, 82))
band0 = hline(30, "Oversold", color=color.rgb(76, 175, 80))
fill(band1, band0, color=f_grad_transp(c_grad, 90), title="Background")

Bacalah mengenai seluruh update Pine pada bagian Catatan Rilis pada Panduan Pengguna.

Beberapa indikator bawaan (Momentum, TRIX, Osilator Harga/Price Oscillator, Osilator Harga Detrended/Detrended Price Oscillator, Oscillator Chaikin/Chaikin Oscillator, Oscillator Volume, Kemudahan Pergerakan/Ease of Movement, Kecepatan Perubahan/Rate of Change) telah diupdate dan kini menggunakan fitur baru ini, anda dapat menambahkannya ke dalam chart anda untuk melihat fungsionalitas dari RGB ini bekerja.

Dan berikut adalah contoh bagus dari indikator dengan warna RGB dari para pengembang di komunitas:

Directional Value oleh RicardoSantos

Color Gradient Framework oleh LucF, untuk PineCoders

Delta Volume Columns Pro oleh LucF

Kami harap fitur baru ini berguna untuk anda. Teruslah kirimkan umpan balik dan saran anda – kami membangun TradingView untuk anda, dan kami selalu senang dapat menerima pendapat anda mengenai update platform kami.