Skrip Pine Kini Menjadi Interaktif

Mode input interaktif baru untuk input harga dan waktu sekarang telah tersedia. Alih-alih memilih harga dan waktu dari widget input, kini anda dapat memilihnya dengan melakukan klik pada chart. Mode interaktif diaktifkan dengan menggunakan confirm = true pada input.time() dan input.price().

Berikut adalah kode untuk indikator VWAP Terjangkar dimana titik jangkarnya diatur secara interaktif, sama seperti alat gambar tersebut: 

//@version=5
indicator("Anchored VWAP", overlay=true)
src = input.source(hlc3, "Source")
startCalculationDate = input.time(timestamp("20 Jan 2021"), "Start Calculation", confirm=true)
vwap_calc() =>
    var srcVolArray = array.new_float(na)
    var volArray = array.new_float(na)
    if startCalculationDate <= time
        array.push(srcVolArray, src*volume)
        array.push(volArray, volume)
    else
        array.clear(srcVolArray), array.clear(volArray)
    array.sum(srcVolArray)/array.sum(volArray)
anchoredVwap = vwap_calc()
plot(anchoredVwap, "VWAP", linewidth=3)

Saat dibutuhkan untuk memilih harga dan waktu secara bersamaan, gunakan parameter inline dengan dilai yang sama pada kedua panggilan fungsinya:

//@version=5
indicator("Point", overlay=true)
myPrice = input.price(100, inline="Point", confirm=true)
myTime = input.time(timestamp("2020-02-20"), inline="Point", confirm=true)
lblText = str.format("Price: {0, number}\nTime: {1, date} {1, time}", myPrice, myTime)
var l1 = label.new(myTime, myPrice, lblText, xloc=xloc.bar_time)

Pengingat akan muncul pada chart untuk memandu para pengguna saat mereka berada dalam mode input interaktif: 

Setelah menambahkan indikatornya dan membuat pilihan interaktif awal pada chart, anda dapat memodifikasi titik pilihannya dengan memilih indikatornya dan memindahkannya didalam chart.

Anda dapat melihat bagaimana fitur baru ini bekerja pada publikasi berikut ini:

CAGR oleh TradingView

AutoTrail oleh Bjorgum

Untuk tetap mendapat informasi tentang fitur-fitur baru Pine, anda dapat memantau Catatan rilis Panduan Pengguna Pine kami. Akun PineCoders juga akan menyiarkan updatenya melalui channel telegram Squawk Box, akun Twitter, dan melalui obrolan publik Skrip Pine di TradingView.

Kami harap fitur yang sangat diminta ini bermanfaat bagi anda. Harap terus memberikan umpan balik dan saran untuk perbaikan kepada kami — kami membangun TradingView untuk anda, dan kami selalu ingin mendengar masukan anda.