Pine Script™ עושה כעת שיפועים אנכיים!

עומסי היתר החדשים הבאים עבור הפונקציה fill() יכולים ליצור מעברי צבע אנכיים:

fill(plot1, plot2, top_value, bottom_value, top_color, bottom_color)

fill(hline1, hline2,  top_value, bottom_value, top_color, bottom_color)

כל הפרמטרים בעומסי היתר החדשים מקבלים ארגומנטים של סדרה. הם יוצרים שיפוע אנכי בין `top_color`ל `bottom_color`ברווח שבין `top_value`לbottom_value“. המתווים או הקווים שבהם נעשה שימוש במזהים בשני הארגומנטים הראשונים פועלים כמסיכה מעל השיפוע, וקובעת איזה חלק מהשיפוע נראה.

ראה כאן כיצד אנו מעניקים ל-MACD הישן מראה חדש עם שני שיפועים אנכיים, אחד כדי למלא את החלל בין שני הממוצעים הנעים, ואחר עבור מה שמוצג בדרך כלל כהיסטוגרמה:

//@version=5
indicator("MACD")
[macd, signal, hist] = ta.macd(close, 12, 26, 9)

// Histogram
float  maxHist  = ta.highest(hist, 100)
float  minHist  = ta.lowest(hist,  100)
bool   histBull = hist > 0
color  topHistColor = histBull ? color.new(color.green, 90) : color.red
color  botHistColor = histBull ? color.green : color.new(color.red, 90)
float  topHistValue = histBull ? maxHist : 0
float  botHistValue = histBull ? 0 : minHist
histPlot   = plot(hist, "Histogram", color(na))
centerPlot = plot(0,    "Middle",    color(na))
fill(histPlot, centerPlot, topHistValue, botHistValue, topHistColor, botHistColor)

// Averages
float  maxLine  = ta.highest(math.max(macd, signal), 100)
float  minLine  = ta.lowest(math.min(macd, signal), 100)
bool   lineBull = macd > signal
color  topLineColor = lineBull ? color.new(color.lime, 90) : color.fuchsia
color  botLineColor = lineBull ? color.lime : color.new(color.fuchsia, 90)
float  topLineValue = lineBull ? maxLine : maxLine
float  botLineValue = lineBull ? minLine : minLine
macdPlot   = plot(macd,   "MACD",   color.gray,   1)
signalPlot = plot(signal, "Signal", color.silver, 1)
fill(macdPlot, signalPlot, topLineValue, botLineValue, topLineColor, botLineColor)

בדוגמה הבאה שלנו, אנו יוצרים Pine באמצעות שיפוע אחד עבור הרקע ואחר עבור קו העצים מבוסס RSI:

//@version=5
indicator("Gradient Fill: Night in the Pine forest")

// Sky
skyTopColor = input.color(color.rgb(144, 191, 249, 1))
skyBotColor = input.color(color.rgb(251, 192, 45, 1))
skyPlot     = plot(100, color = skyTopColor)
groundPlot  = plot(0, color = color.black)
fill(skyPlot, groundPlot, 100, 0, skyTopColor, skyBotColor)

// Trees
crownsVal = ta.rsi(close, 20)
treesPlot = plot(crownsVal, color = color.rgb(6, 126, 116))
fill(treesPlot, groundPlot, crownsVal, 0, color.rgb(6, 126, 116), color.black)

להלן מספר דוגמאות נוספות שפורסמו על ידי כמה מה-PineCoders שלנו בסקריפטים קהילתיים:

אינדיקטור Delta Volume Channels מאת LucF

RSI – אינדיקטור RSI – colour fill מבית Fikira

אינדיקטור RSI של Webby מאת JohnMuchow

כדי להישאר מעודכן בתכונות החדשות של Pine Script™, שימו עין על הערות הגרסה של מדריך למשתמש. חשבון PineCoders משדר גם עדכונים מה-Squawk Box שלו בטלגרם, חשבון הטוויטר שלו, ומהצ’אט הציבורי של Pine Script™ Q&A ב- TradingView.

אנו מקווים שתמצא תכונה מבוקשת זו שימושית. אנא המשיכו לשלוח לנו משוב והצעות לשיפור. אנו בונים עבורך TradingView ותמיד נשמח לשמוע ממך.