Pinho Script™ agora gera gradientes verticais!

Oct 5, 2022

As seguintes novas capacidades para a função fill() permitem a criação de inclinações verticais:

fill(plot1, plot2, top_value, bottom_value, top_color, bottom_color)

fill(hline1, hline2,  top_value, bottom_value, top_color, bottom_color)

Todos os parâmetros nas novas capacidades aceitam argumentos de série. Eles criam um gradiente vertical entre o “top_color” e o “bottom_color” no espaço entre o “top_value” e o “bottom_value”. As tramas ou linhas que são utilizadas nos dois primeiros argumentos atuam como uma máscara sobre o gradiente, determinando qual parte do gradiente é visível.

Veja aqui como damos ao antigo MACD um novo visual com dois gradientes verticais, um para preencher o espaço entre as duas médias móveis, e outro para o que normalmente é representado como um histograma:

//@version=5
indicator("MACD")
[macd, signal, hist] = ta.macd(close, 12, 26, 9)

// Histogram
float  maxHist  = ta.highest(hist, 100)
float  minHist  = ta.lowest(hist,  100)
bool   histBull = hist > 0
color  topHistColor = histBull ? color.new(color.green, 90) : color.red
color  botHistColor = histBull ? color.green : color.new(color.red, 90)
float  topHistValue = histBull ? maxHist : 0
float  botHistValue = histBull ? 0 : minHist
histPlot   = plot(hist, "Histogram", color(na))
centerPlot = plot(0,    "Middle",    color(na))
fill(histPlot, centerPlot, topHistValue, botHistValue, topHistColor, botHistColor)

// Averages
float  maxLine  = ta.highest(math.max(macd, signal), 100)
float  minLine  = ta.lowest(math.min(macd, signal), 100)
bool   lineBull = macd > signal
color  topLineColor = lineBull ? color.new(color.lime, 90) : color.fuchsia
color  botLineColor = lineBull ? color.lime : color.new(color.fuchsia, 90)
float  topLineValue = lineBull ? maxLine : maxLine
float  botLineValue = lineBull ? minLine : minLine
macdPlot   = plot(macd,   "MACD",   color.gray,   1)
signalPlot = plot(signal, "Signal", color.silver, 1)
fill(macdPlot, signalPlot, topLineValue, botLineValue, topLineColor, botLineColor)

Em nosso próximo exemplo, criamos uma Pine forest usando um gradiente para o fundo e outro para a linha da árvore baseada no RSI:
//@version=5
indicator("Gradient Fill: Night in the Pine forest")

// Sky
skyTopColor = input.color(color.rgb(144, 191, 249, 1))
skyBotColor = input.color(color.rgb(251, 192, 45, 1))
skyPlot     = plot(100, color = skyTopColor)
groundPlot  = plot(0, color = color.black)
fill(skyPlot, groundPlot, 100, 0, skyTopColor, skyBotColor)

// Trees
crownsVal = ta.rsi(close, 20)
treesPlot = plot(crownsVal, color = color.rgb(6, 126, 116))
fill(treesPlot, groundPlot, crownsVal, 0, color.rgb(6, 126, 116), color.black)

A seguir, mais alguns exemplos publicados por alguns de nossos PineCoders na Comunidade de Scripts:

Indicador de Canais de Volume Delta de LucF

RSI – indicador de preenchimento por cor de Fikira

Indicador RSI do Webby por JohnMuchow

Para se manter informado sobre os novos recursos do Pine Script™, fique de olho nas notas de lançamento do Manual do Usuário. A conta do PineCoders também transmite atualizações de sua Squawk Box no Telegrama, de sua conta no Twitter, e do chat público do Pine Script™ Q&A no TradingView.

Esperamos que você considere útil este recurso tão solicitado. Por favor, continue nos enviando seus comentários e sugestões para melhorias. Nós construímos o TradingView para você, e estamos sempre ansiosos para ouvir sua opinião.

Look first Then leap

TradingView is built for you, so make sure you're getting the most of our awesome features
Launch Chart