fill() işlevi için aşağıdaki yeni aşırı yüklemeler dikey degradeler oluşturabilir:
fill(plot1, plot2, top_value, bottom_value, top_color, bottom_color) fill(hline1, hline2, top_value, bottom_value, top_color, bottom_color)
Yeni aşırı yüklemelerdeki tüm parametreler seri bağımsız değişkenlerini kabul eder. `top_color` ve `bottom_color` arasındaki boşlukta `top_value` ve `bottom_value` arasında dikey bir gradyan oluştururlar . İlk iki argümanda kullanılan ID’ler veya çizgiler, degradenin hangi bölümünün görünür olduğunu belirleyen degrade üzerinde bir maske görevi görür.
Eski MACD’ye, biri iki hareketli ortalama arasındaki boşluğu doldurmak için, diğeri ise genellikle bir histogram olarak temsil edilen şey için iki dikey gradyanla nasıl yeni bir görünüm kazandırdığımızı görün:
//@version=5
indicator("MACD")
[macd, signal, hist] = ta.macd(close, 12, 26, 9)
// Histogram
float maxHist = ta.highest(hist, 100)
float minHist = ta.lowest(hist, 100)
bool histBull = hist > 0
color topHistColor = histBull ? color.new(color.green, 90) : color.red
color botHistColor = histBull ? color.green : color.new(color.red, 90)
float topHistValue = histBull ? maxHist : 0
float botHistValue = histBull ? 0 : minHist
histPlot = plot(hist, "Histogram", color(na))
centerPlot = plot(0, "Middle", color(na))
fill(histPlot, centerPlot, topHistValue, botHistValue, topHistColor, botHistColor)
// Averages
float maxLine = ta.highest(math.max(macd, signal), 100)
float minLine = ta.lowest(math.min(macd, signal), 100)
bool lineBull = macd > signal
color topLineColor = lineBull ? color.new(color.lime, 90) : color.fuchsia
color botLineColor = lineBull ? color.lime : color.new(color.fuchsia, 90)
float topLineValue = lineBull ? maxLine : maxLine
float botLineValue = lineBull ? minLine : minLine
macdPlot = plot(macd, "MACD", color.gray, 1)
signalPlot = plot(signal, "Signal", color.silver, 1)
fill(macdPlot, signalPlot, topLineValue, botLineValue, topLineColor, botLineColor)
Bir sonraki örneğimizde, arka plan için bir gradyan ve RSI tabanlı ağaç çizgisi için başka bir gradyan kullanarak bir Pine ormanı oluşturuyoruz:
//@version=5
indicator("Gradient Fill: Night in the Pine forest")
// Sky
skyTopColor = input.color(color.rgb(144, 191, 249, 1))
skyBotColor = input.color(color.rgb(251, 192, 45, 1))
skyPlot = plot(100, color = skyTopColor)
groundPlot = plot(0, color = color.black)
fill(skyPlot, groundPlot, 100, 0, skyTopColor, skyBotColor)
// Trees
crownsVal = ta.rsi(close, 20)
treesPlot = plot(crownsVal, color = color.rgb(6, 126, 116))
fill(treesPlot, groundPlot, crownsVal, 0, color.rgb(6, 126, 116), color.black)
Aşağıdakiler, bazı PineCoders’larımız tarafından Topluluk Komut Dosyalarında yayınlanan birkaç örnek daha :
LucF tarafından Delta Hacim Kanalları göstergesi
RSI – Fikira’nın renk doldurma göstergesi
JohnMuchow tarafından Webby’nin RSI göstergesi
Yeni Pine Script™ özelliklerinden haberdar olmak için, Kullanım Kılavuzunun Sürüm notlarına göz atın. PineCoders hesabı ayrıca Telegram’daki Squawk Box’tan , Twitter hesabından ve TradingView’deki Pine Script™ Soru-Cevap genel sohbetinden güncellemeler yayınlar.
Çok istenen bu özelliği yararlı bulacağınızı umuyoruz. Lütfen bize geri bildirimlerinizi ve iyileştirme önerilerinizi göndermeye devam edin. TradingView’i sizin için oluşturuyoruz ve sizden her zaman haber almak isteriz.