September 9, 2020
Mehrere Pinefunktionen unterstützen jetzt Argumente für dynamische Länge

Pine-Coders können jetzt dynamisch berechnete Längen in den folgenden Funktionen verwenden:

alma()
change()
highest()
highestbars()
linreg()
lowest()
lowestbars()
mom()
sma()
sum()
vwma()
wma()

Serien-Längen erleichtern die Erstellung adaptiver Pine-Indikatoren durch Berechnungen auf der Grundlage variabler Perioden. Sehen Sie hier zum Beispiel, wie wir die Volatilität verwenden, um die ALMA-Periode auf der dicken Linie zu verkürzen oder zu verlängern, und vergleichen Sie diese mit der statischen ALMA, die mit der dünnen Linie gezeigt wird:

//@version=4
study("Adaptive ALMA", "AALMA", true)
i_minLen    = input(10, minval = 1)
i_maxLen    = input(60, minval = 1)
i_adaptPct  = input(3., minval = 0, maxval = 100) / 100.0

startingLen = avg(i_minLen, i_maxLen)
var float dynamicLen = startingLen
highVolatility = atr(10) > atr(40)
if highVolatility
    dynamicLen := max(i_minLen, dynamicLen * (1 - i_adaptPct))
else
    dynamicLen := min(i_maxLen, dynamicLen * (1 + i_adaptPct))
dynamicAlma = alma(close, int(dynamicLen),  0.85, 6)
staticAlma  = alma(close, int(startingLen), 0.85, 6)

maColor(_ma) => close > _ma ? highVolatility ? #40FF00ff : #40FF0060 : highVolatility ? #FF0080ff : #FF008060
plot(dynamicAlma, "Dynamic Alma", maColor(dynamicAlma), 3)
plot(staticAlma,  "Static Alma",  maColor(staticAlma),  1)
// Follow the calculated Length in the Data Window.
plotchar(dynamicLen, "dynamicLength", "")

Auch wenn es nützlich sein kann, Fließkommazahlen zur dynamischen Berechnung von Längen zu verwenden, denken Sie bitte daran, diese auf ein „int“ zu casten, bevor Sie sie in Funktions-Calls verwenden, wie wir es in unserem Beispiel tun. Denken Sie auch daran, dass diese Funktionen wie üblich für jeden Balken/Kerze ausgewertet werden müssen, also sollten sie außerhalb von „for“-Loops und „if“-Blöcken verwendet werden, die nicht in jedem Balken/Kerze ausgeführt werden.

Wir hoffen, dass diese von Ihnen gewünschte neue Funktion nützlich ist. Bitte senden Sie uns weiterhin Ihr Feedback zur Verbesserung. Wir haben TradingView für Sie entwickelt und freuen uns, Ihre Meinung zu diesen stark nachgefragten Features unserer Plattform zu hören.

The fastest way to follow markets

Launch Chart