ארגן קלט סקריפט בקטעים ושורות

:עדכון הפיין האחרון שלנו מציג שני שיפורים בקלטים

א.  הפרמטר הקבוצתי החדש מאפשר למתכנתים להגדיר כותרת קטע עבור קבוצת קלטים
ב.  הפרמטר החדש בשורה מאפשר לחבר מספר קלטים בשורה אחת
באמצעות תכונות חדשות אלה תוכלו לארגן קלטים בצורה מסודרת יותר, כפי שאנו עושים כאן עבור
.Auto Fib Retracement  האינדיקטור תיקוני פיבונאצ’י אוטומטים

VWAP השימוש בפרמטרים החדשים בסקריפטים שלך קל! התבונן בדוגמה זו של אינדיקטור ויאפ
:המאפשר למשתמשים לציין את נקודות ההתחלה והסיום של החישובים, ולשלוט בתצוגת העוגנים

//@version=4
study(title = "Custom Period VWAP", shorttitle = "CPVWAP", overlay = true)

src = input(hlc3, "Source", input.source)
enableHighlight = input(true, "Highlight", input.bool, inline = "Highlight")
highlightType = input("Anchors", "", input.string, options = ["Anchors", "Background"], inline = "Highlight")
highlightColor = input(color.red, "", input.color, inline = "Highlight")
useStartPeriodTime = input(true, "Start", input.bool, group = "Date Range", inline = "Start Period")
startPeriodTime = input(timestamp("20 Jan 2021"), "", input.time, group = "Date Range", inline = "Start Period")
useEndPeriodTime = input(true, "End", input.bool, group = "Date Range", inline = "End Period")
endPeriodTime = input(timestamp("20 Feb 2021"), "", input.time, group = "Date Range", inline = "End Period")

start = useStartPeriodTime ? startPeriodTime >= time : false
end = useEndPeriodTime ? endPeriodTime <= time : false
calcPeriod = not start and not end

var srcVolArray = array.new_float(na)
var volArray = array.new_float(na)
var line startAnchor = line.new(na, na, na, na, xloc.bar_time, extend.both, highlightColor, width = 2)
var line endAnchor = line.new(na, na, na, na, xloc.bar_time, extend.both, highlightColor, width = 2)
useBgcolor = false

if calcPeriod
    array.push(srcVolArray, src*volume)
    array.push(volArray, volume)
else
    array.clear(srcVolArray), array.clear(volArray)

customVwap = array.sum(srcVolArray) / array.sum(volArray)
if enableHighlight
    if highlightType == "Anchors"
        if useStartPeriodTime
            line.set_xy1(startAnchor, startPeriodTime, low)
            line.set_xy2(startAnchor, startPeriodTime, high)
        if useEndPeriodTime
            line.set_xy1(endAnchor, not na(customVwap) ? time : line.get_x1(endAnchor), low)
            line.set_xy2(endAnchor, not na(customVwap) ? time : line.get_x1(endAnchor), high)
    if highlightType == "Background"
        useBgcolor :=  true

bgcolor(useBgcolor and calcPeriod ? highlightColor : na, editable = false)
plot(customVwap, title="CPVWAP", color = color.blue, linewidth = 2)

הארגומנט הקבוצתי משמש בשתי דרכים. המחרוזת משמשת ככותרת עבור הקבוצה, והיא מגדירה
.גם אילו קלטים שייכים לקבוצה זו

המשתמשות באותו ארגומנט מוטבע input() כאשר משתמשים בארגומנט מוטבע, כל קריאות ה
קובע את אגדת השדה. אם לא נעשה input() יצטרפו בשורה אחת. ארגומנט הכותרת של כל קריאת
.לא ישמש מקרא לשדה input()  שימוש בארגומנט כותרת בקריאת ה
אינם מתאימים לשורה אחת, חלקם יעטפו לשורה inline אם הקלטים המשולבים באמצעות מוטבע
.הבאה

של מדריך הפניה לפיין. קרא על כל input()  אתה יכול למצוא תיאור של הפרמטרים החדשים בערך של
.כל העדכונים על פיין בהערות השחרור של מדריך למשתמש שלנו

.אנו מקווים כי תכונה זו מאוד מועילה. אנא המשך לשלוח אלינו את המשוב שלך לשיפור
.למשתמשים שלנו ואנחנו אוהבים לשמוע ממך TradingView אנו בונים