Komut Dosyası Girişlerini Bölümler ve Satırlarda Düzenleme

En son Pine güncellememiz, girdilere iki iyileştirme getiriyor:

• Yeni grup parametresi, programcıların bir grup giriş için bir bölüm başlığı tanımlamasına izin verir.
• Yeni çizgi içi parametre, birden çok girişin tek bir satırda birleştirilmesine izin verir.

Bu yeni özellikleri kullanarak, burada Oto Fib Düzeltme göstergesi için yaptığımız gibi, girdileri daha düzenli bir şekilde düzenleyebilirsiniz.

Komut dosyalarınızda yeni parametreleri kullanmak kolaydır! Kullanıcıların hesaplamaların başlangıç ve bitiş noktalarını belirlemesine ve bağlantıların görüntüsünü kontrol etmesine olanak tanıyan bu VWAP göstergesi örneğine bir göz atın:

//@version=4
study(title = "Custom Period VWAP", shorttitle = "CPVWAP", overlay = true)

src = input(hlc3, "Source", input.source)
enableHighlight = input(true, "Highlight", input.bool, inline = "Highlight")
highlightType = input("Anchors", "", input.string, options = ["Anchors", "Background"], inline = "Highlight")
highlightColor = input(color.red, "", input.color, inline = "Highlight")
useStartPeriodTime = input(true, "Start", input.bool, group = "Date Range", inline = "Start Period")
startPeriodTime = input(timestamp("20 Jan 2021"), "", input.time, group = "Date Range", inline = "Start Period")
useEndPeriodTime = input(true, "End", input.bool, group = "Date Range", inline = "End Period")
endPeriodTime = input(timestamp("20 Feb 2021"), "", input.time, group = "Date Range", inline = "End Period")

start = useStartPeriodTime ? startPeriodTime >= time : false
end = useEndPeriodTime ? endPeriodTime <= time : false
calcPeriod = not start and not end

var srcVolArray = array.new_float(na)
var volArray = array.new_float(na)
var line startAnchor = line.new(na, na, na, na, xloc.bar_time, extend.both, highlightColor, width = 2)
var line endAnchor = line.new(na, na, na, na, xloc.bar_time, extend.both, highlightColor, width = 2)
useBgcolor = false

if calcPeriod
    array.push(srcVolArray, src*volume)
    array.push(volArray, volume)
else
    array.clear(srcVolArray), array.clear(volArray)

customVwap = array.sum(srcVolArray) / array.sum(volArray)
if enableHighlight
    if highlightType == "Anchors"
        if useStartPeriodTime
            line.set_xy1(startAnchor, startPeriodTime, low)
            line.set_xy2(startAnchor, startPeriodTime, high)
        if useEndPeriodTime
            line.set_xy1(endAnchor, not na(customVwap) ? time : line.get_x1(endAnchor), low)
            line.set_xy2(endAnchor, not na(customVwap) ? time : line.get_x1(endAnchor), high)
    if highlightType == "Background"
        useBgcolor :=  true

bgcolor(useBgcolor and calcPeriod ? highlightColor : na, editable = false)
plot(customVwap, title="CPVWAP", color = color.blue, linewidth = 2)

Grup argümanı iki şekilde kullanılır. Dize, grubun başlığı olarak kullanılır ve ayrıca hangi girişlerin o gruba ait olduğunu tanımlar.

Bir çizgi içi bağımsız değişken kullanıldığında, aynı çizgi içi bağımsız değişkeni kullanan tüm input() çağrıları tek bir satırda birleştirilecektir. Her input() çağrısının başlık bağımsız değişkeni, alanın göstergesini belirler. input() çağrısında başlık bağımsız değişkeni kullanılmazsa, alan için açıklama kullanılmaz. Çizgi içi kullanılarak birleştirilen girişler bir çizgiye sığmazsa, bunlar diğer çizgiye kaydırılır.

Pine Referans Kılavuzunun input() girişinde yeni parametrelerin açıklamasını bulabilirsiniz.

Kullanım Kılavuzumuzun Sürüm Notlarında Pine ile ilgili tüm güncellemeleri okuyun.

Bu çok istenen özelliği yararlı bulacağınızı umuyoruz. Lütfen iyileştirme için bize geri bildiriminizi göndermeye devam edin. Kullanıcılarımız için TradingView geliştiriyoruz ve sizden haber almayı çok seviyoruz.