تنظيم مدخلات النص البرمجي في أقسام وخطوط

يقدم آخر تحديث لـ Pine تحسينين جديدين على المدخلات:

– تسمح معلمة المجموعة الجديدة new group للمبرمجين بتحديد رأس قسم لمجموعة من المدخلات.
– تسمح المعلمة  new inline الجديدة بضم مدخلات متعددة في سطر واحد.

باستخدام هذه الميزات الجديدة ، يمكنك تنظيم المدخلات بشكل أكثر دقة ، كما نفعل هنا لمؤشر Auto Fib Retracement تصحيحات فيبوناتشي الأوتوماتيكية

استخدام المعلمات الجديدة في البرامج النصية الخاصة بك أمر سهل! ألقِ نظرة على هذا المثال لمؤشر VWAP ، والذي يسمح للمستخدمين بتحديد نقطتي البداية والنهاية للحسابات ، والتحكم في عرض نقاط الربط:

//@version=4
study(title = "Custom Period VWAP", shorttitle = "CPVWAP", overlay = true)

src = input(hlc3, "Source", input.source)
enableHighlight = input(true, "Highlight", input.bool, inline = "Highlight")
highlightType = input("Anchors", "", input.string, options = ["Anchors", "Background"], inline = "Highlight")
highlightColor = input(color.red, "", input.color, inline = "Highlight")
useStartPeriodTime = input(true, "Start", input.bool, group = "Date Range", inline = "Start Period")
startPeriodTime = input(timestamp("20 Jan 2021"), "", input.time, group = "Date Range", inline = "Start Period")
useEndPeriodTime = input(true, "End", input.bool, group = "Date Range", inline = "End Period")
endPeriodTime = input(timestamp("20 Feb 2021"), "", input.time, group = "Date Range", inline = "End Period")

start = useStartPeriodTime ? startPeriodTime >= time : false
end = useEndPeriodTime ? endPeriodTime <= time : false
calcPeriod = not start and not end

var srcVolArray = array.new_float(na)
var volArray = array.new_float(na)
var line startAnchor = line.new(na, na, na, na, xloc.bar_time, extend.both, highlightColor, width = 2)
var line endAnchor = line.new(na, na, na, na, xloc.bar_time, extend.both, highlightColor, width = 2)
useBgcolor = false

if calcPeriod
    array.push(srcVolArray, src*volume)
    array.push(volArray, volume)
else
    array.clear(srcVolArray), array.clear(volArray)

customVwap = array.sum(srcVolArray) / array.sum(volArray)
if enableHighlight
    if highlightType == "Anchors"
        if useStartPeriodTime
            line.set_xy1(startAnchor, startPeriodTime, low)
            line.set_xy2(startAnchor, startPeriodTime, high)
        if useEndPeriodTime
            line.set_xy1(endAnchor, not na(customVwap) ? time : line.get_x1(endAnchor), low)
            line.set_xy2(endAnchor, not na(customVwap) ? time : line.get_x1(endAnchor), high)
    if highlightType == "Background"
        useBgcolor :=  true

bgcolor(useBgcolor and calcPeriod ? highlightColor : na, editable = false)
plot(customVwap, title="CPVWAP", color = color.blue, linewidth = 2)

يتم استخدام حجة المجموعة group argument بطريقتين. يتم استخدام السلسلة كرأس للمجموعة ، كما أنها تحدد المدخلات التي تنتمي إلى تلك المجموعة.

عند استخدام وسيطة مضمنة ، سيتم ضم جميع استدعاءات input() التي تستخدم نفس الوسيطة المضمنة في سطر واحد. تحدد وسيطة العنوان لكل استدعاء input() وسيلة إيضاح الحقل. إذا لم يتم استخدام وسيطة العنوان في استدعاء input() ، فلن يتم استخدام وسيلة إيضاح للحقل. إذا كانت المدخلات المجمعة باستخدام مضمنة لا تتناسب مع سطر واحد ، فسيتم التفاف بعضها في السطر التالي.

يمكنك العثور على وصف للمعلمات الجديدة في دليل Pine المرجعي لـ input().

اقرأ عن كافة التحديثات التي تم إجراؤها على Pine في ملاحظات الإصدار الخاصة بدليل المستخدم.

نأمل أن تجد هذه الميزة الأكثر طلبًا مفيدة.

يرجى الاستمرار في إرسال ملاحظاتك إلينا للتحسين.

 نحن نبني TradingView لمستخدمينا ونحب أن نسمع منك.