Sắp xếp đầu vào tập lệnh trong các phần và dòng

Bản cập nhật Pine mới nhất của chúng tôi giới thiệu hai cải tiến đối với đầu vào:

• Tham sốgroup mới cho phép bạn lập trình xác định tiêu đề phần cho một nhóm đầu vào.
• Tham số inline mới cho phép nhiều đầu vào được kết hợp trên một dòng. 

Sử dụng các tính năng mới này, bạn có thể sắp xếp đầu vào gọn gàng hơn, như chúng tôi đang thực hiện ở đây cho chỉ báo Auto Fib Retracement.

Using the new parameters in your scripts is easy! Take a look at this example of a VWAP indicator, which allows users to specify the start and end points of calculations, and control the display of anchors:

//@version=4
study(title = "Custom Period VWAP", shorttitle = "CPVWAP", overlay = true)

src = input(hlc3, "Source", input.source)
enableHighlight = input(true, "Highlight", input.bool, inline = "Highlight")
highlightType = input("Anchors", "", input.string, options = ["Anchors", "Background"], inline = "Highlight")
highlightColor = input(color.red, "", input.color, inline = "Highlight")
useStartPeriodTime = input(true, "Start", input.bool, group = "Date Range", inline = "Start Period")
startPeriodTime = input(timestamp("20 Jan 2021"), "", input.time, group = "Date Range", inline = "Start Period")
useEndPeriodTime = input(true, "End", input.bool, group = "Date Range", inline = "End Period")
endPeriodTime = input(timestamp("20 Feb 2021"), "", input.time, group = "Date Range", inline = "End Period")

start = useStartPeriodTime ? startPeriodTime >= time : false
end = useEndPeriodTime ? endPeriodTime <= time : false
calcPeriod = not start and not end

var srcVolArray = array.new_float(na)
var volArray = array.new_float(na)
var line startAnchor = line.new(na, na, na, na, xloc.bar_time, extend.both, highlightColor, width = 2)
var line endAnchor = line.new(na, na, na, na, xloc.bar_time, extend.both, highlightColor, width = 2)
useBgcolor = false

if calcPeriod
    array.push(srcVolArray, src*volume)
    array.push(volArray, volume)
else
    array.clear(srcVolArray), array.clear(volArray)

customVwap = array.sum(srcVolArray) / array.sum(volArray)
if enableHighlight
    if highlightType == "Anchors"
        if useStartPeriodTime
            line.set_xy1(startAnchor, startPeriodTime, low)
            line.set_xy2(startAnchor, startPeriodTime, high)
        if useEndPeriodTime
            line.set_xy1(endAnchor, not na(customVwap) ? time : line.get_x1(endAnchor), low)
            line.set_xy2(endAnchor, not na(customVwap) ? time : line.get_x1(endAnchor), high)
    if highlightType == "Background"
        useBgcolor :=  true

bgcolor(useBgcolor and calcPeriod ? highlightColor : na, editable = false)
plot(customVwap, title="CPVWAP", color = color.blue, linewidth = 2)

Đối số nhóm được sử dụng theo hai cách. Chuỗi được sử dụng làm tiêu đề cho nhóm và nó cũng xác định đầu vào nào thuộc nhóm đó.

Khi inline được sử dụng, tất cả input() sử dụng cùng một inline sẽ nằm trên một dòng. Đối số title của mỗi input() xác định chú giải của trường. Nếu không có đối số title được sử dụng trong input() thì call, không có chú giải nào sẽ được sử dụng cho trường. Nếu đầu vào kết hợp sử dụng inline không phù hợp trong một dòng thì một số chúng sẽ bị gói lại phần tiếp theo.

Bạn có thể tìm thấy mô tả về các thông số mới trong mục nhập của Pine Reference Manual cho input().

Đọc tất cả về cập nhật của Pine trong Ghi chú Hướng dẫn sử dụng

Chúng tôi hy vọng bạn thấy tính năng này hữu ích. Vui lòng tiếp tục gửi cho chúng tôi phản hồi của bạn để chúng tôi có thể cải thiện nhiều hơn. Chúng tôi xây dựng TradingView cho người dùng của mình và chúng tôi muốn lắng nghe ý kiến của bạn.