Verknüpfen und Annotieren: Pine Tables unterstützen jetzt Kopfzeilen und Tooltips

Kopfzeilen und Zellzusammenführung

Es ist jetzt möglich, mehrere Zellen in einer Tabelle zu verschmelzen, um ausgefallene Kopfzeilen und Trennlinien zu erstellen. Eine verschmolzene Zelle muss jedoch keine Kopfzeile sein: Sie können Zellen in jeder Richtung verschmelzen, solange die resultierende Zelle keine bereits verschmolzenen Zellen beeinflusst und nicht über die Grenzen der Tabelle hinausgeht.

Um eine zusammengeführte Zelle zu erstellen, verwenden Sie die neue Funktion table.merge_cells(). Die Regeln sind einfach. Sie müssen die Koordinaten der ersten und der letzten Zelle, die Sie zusammenführen wollen, übergeben. Alles, was dazwischen liegt, wird zu einer einzigen Zelle zusammengeführt. Die Größe einer zusammengeführten Zelle wird automatisch durch die Abmessungen ihrer benachbarten Zeilen und Spalten bestimmt.

Im Beispielskript unten sehen Sie drei zusammengeführte Zellen: Die erste führt alle Zellen in Zeile Null zusammen und enthält „SMA Table“, die anderen darunter bilden die Zwischenüberschriften.

//@version=5
indicator("MA Ratings", overlay = true)

TRANSP = 80
TABLE_WIDTH = 6
var CELL_TOOLTIP = "Cell color depends on the SMA direction: green for rising SMAs, red for falling ones"

var smaLengths = array.from(10, 20, 50, 100, 200, 500)

smaValues = array.new_float()
for i = 0 to array.size(smaLengths) - 1
    array.push(smaValues, ta.sma(close, array.get(smaLengths, i)))

var maTable = table.new(position.top_right, TABLE_WIDTH, 4, border_width = 2)

if barstate.isfirst
    headerColor = color.new(color.blue, TRANSP)
    table.cell(maTable, 0, 0, text = "SMA Table", bgcolor = headerColor)
    table.cell(maTable, 0, 1, text = "Short-term", bgcolor = headerColor)
    table.cell(maTable, 2, 1, text = "Long-term", bgcolor = headerColor)
    table.merge_cells(maTable, 0, 0, 5, 0)
    table.merge_cells(maTable, 0, 1, 1, 1)
    table.merge_cells(maTable, 2, 1, 5, 1)

if barstate.islast
    for i = 0 to TABLE_WIDTH - 1
        cellTitle = str.format("SMA {0}", array.get(smaLengths, i))
        cellValue = array.get(smaValues, i)
        cellColor = color.new(array.get(smaValues, i) >= array.get(smaValues[1], i) ? color.green : color.red, TRANSP)
        table.cell(maTable, i, 2, bgcolor = cellColor, text = cellTitle, text_color = color.gray, tooltip = CELL_TOOLTIP)
        table.cell(maTable, i, 3, bgcolor = cellColor, text = str.tostring(cellValue,  format.mintick), tooltip = CELL_TOOLTIP)

Tooltips

Die zweite Verbesserung der Tabellen sind Tooltips. Tooltips sind schwebende Textbeschriftungen, die erscheinen, wenn Sie den Mauszeiger über die Zelle einer Tabelle bewegen. Sie sind praktisch, um Informationen über den Inhalt einer Zelle bereitzustellen, ohne die Tabelle zu überladen.

Um eine Zelle mit einer QuickInfo zu erstellen, übergeben Sie einfach einen String an das neue tooltip Argument der table.cell() Funktion. Sehen Sie Tooltips in Aktion in unserem Beispielskript, wo wir tooltip = CELL_TOOLTIP in der table.cell() der letzten beiden Zeilen verwenden. Die Tooltips sehen dann wie folgt aus

Um über neue Pine-Funktionen auf dem Laufenden zu bleiben, sollten Sie die Versionshinweise in unserem Pine-Benutzerhandbuch im Blick behalten. Der PineCoders Account sendet auch Updates in die Squawk Box auf Telegram, den offiziellen Twitter Account, und über den öffentlichen Pine Script Chat auf TradingView.

Wir hoffen, dass Sie diese stark nachgefragte Funktion nützlich finden werden. Bitte senden Sie uns weiterhin Ihr Feedback und Ihre Verbesserungsvorschläge. Wir entwickeln TradingView für Sie und wir sind immer daran interessiert, von Ihnen zu hören.