Hợp nhất và chú thích: Bảng Pine hiện hỗ trợ tiêu đề và chú giải công cụ

Tiêu đề và hợp nhất ô

Giờ đây, có thể hợp nhất một số ô trong một bảng để tạo các tiêu đề và dấu phân cách lạ mắt. Tuy nhiên, một ô đã hợp nhất không nhất thiết phải là tiêu đề: bạn có thể hợp nhất các ô theo bất kỳ hướng nào, miễn là ô kết quả không ảnh hưởng đến bất kỳ ô nào đã được hợp nhất và không đi ra ngoài giới hạn của bảng.

Để tạo một ô đã hợp nhất, hãy sử dụng hàm table.merge_cells() mới. Các quy tắc rất đơn giản. Bạn cần chuyển tọa độ của ô đầu tiên và ô cuối cùng mà bạn muốn hợp nhất. Mọi thứ giữa chúng sẽ được hợp nhất thành một ô duy nhất. Kích thước của ô đã hợp nhất này được tự động xác định bởi kích thước của các hàng và cột lân cận.

Trong tập lệnh ví dụ bên dưới, bạn có thể thấy ba ô được hợp nhất: ô đầu tiên hợp nhất tất cả các ô ở hàng 0 và chứa “Bảng SMA”, các ô khác bên dưới tạo tiêu đề phụ.

 

//@version=5
indicator("MA Ratings", overlay = true)

TRANSP = 80
TABLE_WIDTH = 6
var CELL_TOOLTIP = "Cell color depends on the SMA direction: green for rising SMAs, red for falling ones"

var smaLengths = array.from(10, 20, 50, 100, 200, 500)

smaValues = array.new_float()
for i = 0 to array.size(smaLengths) - 1
    array.push(smaValues, ta.sma(close, array.get(smaLengths, i)))

var maTable = table.new(position.top_right, TABLE_WIDTH, 4, border_width = 2)

if barstate.isfirst
    headerColor = color.new(color.blue, TRANSP)
    table.cell(maTable, 0, 0, text = "SMA Table", bgcolor = headerColor)
    table.cell(maTable, 0, 1, text = "Short-term", bgcolor = headerColor)
    table.cell(maTable, 2, 1, text = "Long-term", bgcolor = headerColor)
    table.merge_cells(maTable, 0, 0, 5, 0)
    table.merge_cells(maTable, 0, 1, 1, 1)
    table.merge_cells(maTable, 2, 1, 5, 1)

if barstate.islast
    for i = 0 to TABLE_WIDTH - 1
        cellTitle = str.format("SMA {0}", array.get(smaLengths, i))
        cellValue = array.get(smaValues, i)
        cellColor = color.new(array.get(smaValues, i) >= array.get(smaValues[1], i) ? color.green : color.red, TRANSP)
        table.cell(maTable, i, 2, bgcolor = cellColor, text = cellTitle, text_color = color.gray, tooltip = CELL_TOOLTIP)
        table.cell(maTable, i, 3, bgcolor = cellColor, text = str.tostring(cellValue,  format.mintick), tooltip = CELL_TOOLTIP)

Chú giải công cụ

Cải tiến thứ hai đối với bảng là chú giải công cụ. Chú giải công cụ là các nhãn văn bản nổi xuất hiện khi bạn di chuột qua ô của bảng. Chúng rất tiện dụng để cung cấp thông tin về nội dung của ô mà không làm chật bảng.

Để tạo ô có chú giải công cụ, chỉ cần truyền một chuỗi vào đối số chú giải công cụ mới của hàm table.cell(). Xem chú giải công cụ đang hoạt động trong tập lệnh mẫu của chúng tôi, nơi chúng tôi sử dụng tooltip = CELL_TOOLTIP trong lệnh gọi table.cell() của hai dòng cuối cùng. Chú giải công cụ sẽ giống như sau:

Để được cập nhật về các tính năng mới của Pine, hãy theo dõi các ghi chú hướng dẫn sử dụng Pine của chúng tôi. Tài khoản PineCoders cũng phát các bản cập nhật từ Squawk Box trên Telegram, tài khoản Twitter và từ cuộc trò chuyện công khai Pine Script trên TradingView.

Chúng tôi hy vọng bạn thấy tính năng được yêu cầu cao này hữu ích. Hãy tiếp tục gửi cho chúng tôi phản hồi và đề xuất của bạn để cải thiện. Chúng tôi xây dựng TradingView cho bạn và chúng tôi luôn mong muốn nhận được phản hồi từ bạn.