Gabungkan dan beri anotasi: Tabel Pine sekarang mendukung header dan tooltips

HEADER DAN PENGGABUNGAN SEL

Sekarang memungkinkan untuk menggabungkan beberapa sel dalam tabel untuk membuat header dan pemisah yang mewah. Sel yang digabungkan tidak harus berupa header: anda dapat menggabungkan sel ke segala arah, selama sel yang dihasilkan tidak mempengaruhi sel yang sudah digabungkan, dan tidak keluar dari batas tabel.

Untuk membuat sel gabungan, gunakan fungsi table.merge_cells() baru. Aturannya sederhana. Anda harus melewati koordinat sel pertama dan terakhir yang ingin anda gabungkan. Segala sesuatu di antara mereka akan digabungkan menjadi satu sel. Ukuran sel gabungan ini secara otomatis ditentukan oleh dimensi baris dan kolom di sekitarnya.

Dalam contoh skrip di bawah ini, anda dapat melihat tiga sel yang digabungkan: yang pertama menggabungkan semua sel di row nol dan berisi “Tabel SMA”, yang lain di bawahnya membuat sub-header.

//@version=5
indicator("MA Ratings", overlay = true)

TRANSP = 80
TABLE_WIDTH = 6
var CELL_TOOLTIP = "Cell color depends on the SMA direction: green for rising SMAs, red for falling ones"

var smaLengths = array.from(10, 20, 50, 100, 200, 500)

smaValues = array.new_float()
for i = 0 to array.size(smaLengths) - 1
    array.push(smaValues, ta.sma(close, array.get(smaLengths, i)))

var maTable = table.new(position.top_right, TABLE_WIDTH, 4, border_width = 2)

if barstate.isfirst
    headerColor = color.new(color.blue, TRANSP)
    table.cell(maTable, 0, 0, text = "SMA Table", bgcolor = headerColor)
    table.cell(maTable, 0, 1, text = "Short-term", bgcolor = headerColor)
    table.cell(maTable, 2, 1, text = "Long-term", bgcolor = headerColor)
    table.merge_cells(maTable, 0, 0, 5, 0)
    table.merge_cells(maTable, 0, 1, 1, 1)
    table.merge_cells(maTable, 2, 1, 5, 1)

if barstate.islast
    for i = 0 to TABLE_WIDTH - 1
        cellTitle = str.format("SMA {0}", array.get(smaLengths, i))
        cellValue = array.get(smaValues, i)
        cellColor = color.new(array.get(smaValues, i) >= array.get(smaValues[1], i) ? color.green : color.red, TRANSP)
        table.cell(maTable, i, 2, bgcolor = cellColor, text = cellTitle, text_color = color.gray, tooltip = CELL_TOOLTIP)
        table.cell(maTable, i, 3, bgcolor = cellColor, text = str.tostring(cellValue,  format.mintick), tooltip = CELL_TOOLTIP)

TOOLTIPS

Peningkatan kedua pada tabel adalah tooltips. Tooltips adalah label teks mengambang yang muncul saat anda mengarahkan kursor ke sel tabel. Mereka berguna untuk menyediakan informasi tentang konten sel tanpa memenuhi tabel.

Untuk membuat sel dengan tooltip, cukup berikan string ke argumen tooltip baru dari fungsi table.cell(). Lihatlah tooltips beraksi dalam skrip contoh kami, di mana kami menggunakan tooltip = CELL_TOOLTIP dalam panggilan table.cell() dari dua baris terakhir. Tooltips akan terlihat seperti ini:

Untuk tetap mendapat informasi tentang fitur-fitur baru Pine, pantau Catatan rilis Panduan Pengguna Pine kami. Akun PineCoders juga menyiarkan pembaruan dari Squawk Box di Telegram, akun Twitter, dan dari obrolan publik Skrip Pine di TradingView.

Kami harap fitur yang sangat diminta ini bermanfaat bagi anda. Harap terus mengirimkan umpan balik dan saran anda untuk peningkatan kami. Kami membangun TradingView untuk anda, dan kami selalu ingin mendengar dari anda.