تدعم جداول باين البرمجية الآن الهوامش وتلميحات الأدوات

من الممكن الآن دمج عدة خلايا في جدول لإنشاء هوامش علوية وفواصل رائعة. لا يجب أن تكون الخلية المدمجة رأسًا على الرغم من ذلك: يمكنك دمج الخلايا في أي اتجاه ، طالما أن الخلية الناتجة لا تؤثر على أي خلايا مدمجة بالفعل، ولا تخرج خارج حدود الجدول.

لإنشاء خلية مدمجة ، استخدم الدالة table.merge_cells() الجديدة. القواعد بسيطة. تحتاج إلى تمرير إحداثيات الخلية الأولى والأخيرة التي تريد دمجها. سيتم دمج كل شيء بينهما في خلية واحدة. يتم تحديد حجم الخلية المدمجة تلقائيًا من خلال أبعاد الصفوف والأعمدة المجاورة لها.

في المثال النصي أدناه، يمكنك رؤية ثلاث خلايا مدمجة: الأولى تدمج جميع الخلايا في الصف صفر وتحتوي على “جدول SMA” ، بينما تنشئ الخلايا الأخرى الموجودة أسفلها الهوامش الفرعية.

//@version=5
indicator("MA Ratings", overlay = true)

TRANSP = 80
TABLE_WIDTH = 6
var CELL_TOOLTIP = "Cell color depends on the SMA direction: green for rising SMAs, red for falling ones"

var smaLengths = array.from(10, 20, 50, 100, 200, 500)

smaValues = array.new_float()
for i = 0 to array.size(smaLengths) - 1
    array.push(smaValues, ta.sma(close, array.get(smaLengths, i)))

var maTable = table.new(position.top_right, TABLE_WIDTH, 4, border_width = 2)

if barstate.isfirst
    headerColor = color.new(color.blue, TRANSP)
    table.cell(maTable, 0, 0, text = "SMA Table", bgcolor = headerColor)
    table.cell(maTable, 0, 1, text = "Short-term", bgcolor = headerColor)
    table.cell(maTable, 2, 1, text = "Long-term", bgcolor = headerColor)
    table.merge_cells(maTable, 0, 0, 5, 0)
    table.merge_cells(maTable, 0, 1, 1, 1)
    table.merge_cells(maTable, 2, 1, 5, 1)

if barstate.islast
    for i = 0 to TABLE_WIDTH - 1
        cellTitle = str.format("SMA {0}", array.get(smaLengths, i))
        cellValue = array.get(smaValues, i)
        cellColor = color.new(array.get(smaValues, i) >= array.get(smaValues[1], i) ? color.green : color.red, TRANSP)
        table.cell(maTable, i, 2, bgcolor = cellColor, text = cellTitle, text_color = color.gray, tooltip = CELL_TOOLTIP)
        table.cell(maTable, i, 3, bgcolor = cellColor, text = str.tostring(cellValue,  format.mintick), tooltip = CELL_TOOLTIP)

تلميحات الأدوات

التحسين الثاني للجداول هو تلميحات الأدوات. تلميحات الأدوات عبارة عن تسميات نصية عائمة تظهر عند التمرير فوق خلية جدول. إنها سهلة الاستخدام لتوفير معلومات حول محتوى الخلية دون ازدحام الجدول.

لإنشاء خلية مع تلميح أداة ، ما عليك سوى تمرير سلسلة إلى وسيطة tooltip الجديدة لدالة table.cell (). انظر إلى تلميحات الأدوات قيد التنفيذ في مثالنا النصي ، حيث نستخدم  tooltip = CELL_TOOLTIP  في استدعاء table.cell () للسطرين الأخيرين. ستبدو التلميحات بالشكل التالي:

 

 

للبقاء على اطلاع بميزات Pine الجديدة ، راقب ملاحظات إصدار دليل مستخدم Pine. يبث حساب PineCoders أيضًا تحديثات من Squawk Box على Telegram وحسابه على Twitter ومن الدردشة العامة Pine Script على TradingView.

نأمل أن تجد هذه الميزة المطلوبة بشدة مفيدة.

يرجى الاستمرار في إرسال ملاحظاتك واقتراحاتك إلينا للتحسين.

 نحن نبني TradingView لك ونحن حريصون دائمًا على الاستماع إليك.