合併和註釋：Pine表格現在支持標題和工具提示

標題和單元格合併

現在可以合併表格中的多個單元格以建立精美的標題和分隔符號。合併的單元格不一定是標題：您可以在任何方向合併單元格，只要生成的單元格不影響任何已合併的單元格，並且不會超出表格的範圍。

要建立合併單元格，請使用新的 table.merge_cells() 函數。規則很簡單。您需要傳遞要合併的第一個和最後一個單元格的坐標。它們之間的所有內容都將合併到一個單元格中。合併單元格的大小由其相鄰欄和列的尺寸自動確定。

在下面的示例腳本中，您可以看到三個合併的單元格：第一個合併第零行中的所有單元格並包含“SMA 表格”，下面的其他單元格建立子標題。

//@version=5
indicator("MA Ratings", overlay = true)

TRANSP = 80
TABLE_WIDTH = 6
var CELL_TOOLTIP = "Cell color depends on the SMA direction: green for rising SMAs, red for falling ones"

var smaLengths = array.from(10, 20, 50, 100, 200, 500)

smaValues = array.new_float()
for i = 0 to array.size(smaLengths) - 1
    array.push(smaValues, ta.sma(close, array.get(smaLengths, i)))

var maTable = table.new(position.top_right, TABLE_WIDTH, 4, border_width = 2)

if barstate.isfirst
    headerColor = color.new(color.blue, TRANSP)
    table.cell(maTable, 0, 0, text = "SMA Table", bgcolor = headerColor)
    table.cell(maTable, 0, 1, text = "Short-term", bgcolor = headerColor)
    table.cell(maTable, 2, 1, text = "Long-term", bgcolor = headerColor)
    table.merge_cells(maTable, 0, 0, 5, 0)
    table.merge_cells(maTable, 0, 1, 1, 1)
    table.merge_cells(maTable, 2, 1, 5, 1)

if barstate.islast
    for i = 0 to TABLE_WIDTH - 1
        cellTitle = str.format("SMA {0}", array.get(smaLengths, i))
        cellValue = array.get(smaValues, i)
        cellColor = color.new(array.get(smaValues, i) >= array.get(smaValues[1], i) ? color.green : color.red, TRANSP)
        table.cell(maTable, i, 2, bgcolor = cellColor, text = cellTitle, text_color = color.gray, tooltip = CELL_TOOLTIP)
        table.cell(maTable, i, 3, bgcolor = cellColor, text = str.tostring(cellValue,  format.mintick), tooltip = CELL_TOOLTIP)

工具提示

對表格的第二個改進是工具提示。工具提示是當您將滑鼠懸停在表格的單元格上時出現的浮動文字標籤。它們可以方便地提供有關單元格內容的信息，而不會讓表格擁擠。

要建立帶有工具提示的單元格，只需將字串傳遞給 table.cell() 函數的新 tooltip 參數。在我們的示例腳本中查看實際的工具提示，我們在最後兩行的 table.cell() 調用中使用 tooltip = CELL_TOOLTIP。工具提示將如下所示：

要隨時了解Pine的新功能，請留意我們的Pine用戶手冊的發行說明。PineCoders帳戶還從Telegram上的Squawk Box、Twitter帳戶和TradingView上的Pine腳本公開聊天中廣播更新。

我們希望大家發現這個高需求的功能很有用。請繼續向我們發送您的反饋和改進建議。我們為您打造TradingView，總是渴望收到您的訊息。