Birleştirin ve açıklama ekleyin: Pine Tables artık başlıkları ve araç ipuçlarını destekliyor

Başlıklar ve hücre birleştirme

Süslü üstbilgiler ve ayırıcılar oluşturmak için tablodaki birkaç hücreyi birleştirmek artık mümkündür. Birleştirilmiş bir hücrenin üstbilgi olması gerekmez: elde eden hücre zaten birleştirilmiş hücreleri etkilemediği ve tablonun sınırlarının dışına çıkmadığı sürece hücreleri herhangi bir yönde birleştirebilirsiniz.

Birleştirilmiş hücre oluşturmak için yeni table.merge_cells() işlevini kullanın. Kurallar basit. Birleştirmek istediğiniz ilk ve son hücrenin koordinatlarını geçirmeniz gerekir. Aralarındaki her şey tek bir hücrede birleştirilecek. Birleştirilmiş bir hücrenin bu boyutu, komşu satır ve sütunlarının boyutları tarafından otomatik olarak belirlenir.

Aşağıdaki örnek komut dosyasında, üç birleştirilmiş hücre görebilirsiniz: birincisi sıfır satırındaki tüm hücreleri birleştirir ve “SMA Tablosu” içerir, altındaki diğerleri alt başlıkları oluşturur.

//@version=5
indicator("MA Ratings", overlay = true)

TRANSP = 80
TABLE_WIDTH = 6
var CELL_TOOLTIP = "Hücre rengi SMA yönüne bağlıdır: yükselen SMA'lar için yeşil, düşenler için kırmızı"

var smaLengths = array.from(10, 20, 50, 100, 200, 500)

smaValues = array.new_float()
for i = 0 to array.size(smaLengths) - 1
    array.push(smaValues, ta.sma(close, array.get(smaLengths, i)))

var maTable = table.new(position.top_right, TABLE_WIDTH, 4, border_width = 2)

if barstate.isfirst
    headerColor = color.new(color.blue, TRANSP)
    table.cell(maTable, 0, 0, text = "SMA Table", bgcolor = headerColor)
    table.cell(maTable, 0, 1, text = "Short-term", bgcolor = headerColor)
    table.cell(maTable, 2, 1, text = "Long-term", bgcolor = headerColor)
    table.merge_cells(maTable, 0, 0, 5, 0)
    table.merge_cells(maTable, 0, 1, 1, 1)
    table.merge_cells(maTable, 2, 1, 5, 1)

if barstate.islast
    for i = 0 to TABLE_WIDTH - 1
        cellTitle = str.format("SMA {0}", array.get(smaLengths, i))
        cellValue = array.get(smaValues, i)
        cellColor = color.new(array.get(smaValues, i) >= array.get(smaValues[1], i) ? color.green : color.red, TRANSP)
        table.cell(maTable, i, 2, bgcolor = cellColor, text = cellTitle, text_color = color.gray, tooltip = CELL_TOOLTIP)
        table.cell(maTable, i, 3, bgcolor = cellColor, text = str.tostring(cellValue,  format.mintick), tooltip = CELL_TOOLTIP)

İpuçları

Tablolardaki ikinci geliştirme araç ipuçlarıdır. Araç ipuçları, tablonun hücresinin üzerine geldiğinizde görüntülenen kayan metin etiketleridir. Fazla abartmadan bir hücrenin içeriği hakkında bilgi sağlamak için kullanışlıdırlar.

Araç ipucu içeren bir hücre oluşturmak için, table.cell() işlevinin yeni tooltip bağımsız değişkenine bir dize geçirmeniz yeterlidir. Son iki satırın table.cell() çağrısında araç tooltip = CELL_TOOLTIP kullandığımız örnek komut dosyamızda araç ipuçlarını çalışırken görün. Araç ipuçları şöyle görünecektir:

Yeni Pine özelliklerinden haberdar olmak için Pine Kullanım Kılavuzumuzun Sürüm notlarına göz kulak olun. PineCoders hesabı ayrıca Telegram’daki Squawk Box’ından, Twitter hesabından ve TradingView’deki Pine Script genel sohbetinden güncellemeler yayınlar.

Umarız bu çok istenen özelliği yararlı bulursunuz. Lütfen iyileştirme için geri bildirimlerinizi ve önerilerinizi bize göndermeye devam edin. TradingView’i sizin için oluşturuyoruz ve sizden her zaman haber almak istiyoruz.