Połącz i komentuj: Tabele Pine mogą teraz łączyć komórki i dodawać podpowiedzi

NAGŁÓWKI I SCALANIE KOMÓREK

Pine umożliwia teraz łączenie wielu komórek w tabeli w jedną w celu tworzenia nagłówków i separatorów. Jednak scalona komórka nie musi być nagłówkiem, można je scalić w dowolnym kierunku, o ile wynikowa komórka nie wpływa na żadne już scalone komórki i nie wychodzi poza granice tabeli.

Aby utworzyć scaloną komórkę, użyj nowej funkcji table.merge_cells(). Zasady są proste: funkcji należy przekazać współrzędne pierwszej i ostatniej komórki tych, które mają zostać połączone. Wszystko pomiędzy zostanie połączone. Rozmiar wynikowej komórki jest automatycznie określany przez rozmiar sąsiednich wierszy i kolumn.

W poniższym przykładowym skrypcie widać trzy scalone komórki: pierwsza tworzy nagłówek tabeli, grupując wszystkie komórki w wierszu 0 i zawiera tekst „SMA Table”, pozostałe dwie tworzą podnagłówki.

//@version=5
indicator("MA Ratings", overlay = true)

TRANSP = 80
TABLE_WIDTH = 6
var CELL_TOOLTIP = "Cell color depends on the SMA direction: green for rising SMAs, red for falling ones"

var smaLengths = array.from(10, 20, 50, 100, 200, 500)

smaValues = array.new_float()
for i = 0 to array.size(smaLengths) - 1
    array.push(smaValues, ta.sma(close, array.get(smaLengths, i)))

var maTable = table.new(position.top_right, TABLE_WIDTH, 4, border_width = 2)

if barstate.isfirst
    headerColor = color.new(color.blue, TRANSP)
    table.cell(maTable, 0, 0, text = "SMA Table", bgcolor = headerColor)
    table.cell(maTable, 0, 1, text = "Short-term", bgcolor = headerColor)
    table.cell(maTable, 2, 1, text = "Long-term", bgcolor = headerColor)
    table.merge_cells(maTable, 0, 0, 5, 0)
    table.merge_cells(maTable, 0, 1, 1, 1)
    table.merge_cells(maTable, 2, 1, 5, 1)

if barstate.islast
    for i = 0 to TABLE_WIDTH - 1
        cellTitle = str.format("SMA {0}", array.get(smaLengths, i))
        cellValue = array.get(smaValues, i)
        cellColor = color.new(array.get(smaValues, i) >= array.get(smaValues[1], i) ? color.green : color.red, TRANSP)
        table.cell(maTable, i, 2, bgcolor = cellColor, text = cellTitle, text_color = color.gray, tooltip = CELL_TOOLTIP)
        table.cell(maTable, i, 3, bgcolor = cellColor, text = str.tostring(cellValue,  format.mintick), tooltip = CELL_TOOLTIP)

PODPOWIEDZI

Drugie ulepszenie tabeli to podpowiedzi, które pojawiają się po najechaniu kursorem na komórkę tabeli. Za ich pomocą możesz wygodnie podać dodatkowe informacje o zawartości komórki bez przeciążania samej tabeli.

Aby utworzyć komórkę podpowiedzi, po prostu przekaż ciąg do nowego argumentu podpowiedzi funkcji tooltip table.cell(). Zobacz podpowiedzi w akcji w naszym przykładowym skrypcie, w którym używamy tooltip = CELL_TOOLTIP w wywołaniu table.cell() w ostatnich dwóch wierszach. Podpowiedzi będą wyglądać tak:

Aby być na bieżąco z nowymi funkcjami Pine, zapoznaj się z informacjami o wydaniu naszego Podręcznika użytkownika Pine. Konto PineCoders transmituje również aktualizacje ze swojego Squawk Box’a na Telegramie, swojego konta na Twitterze oraz z publicznego czatu Pine Script na TradingView.

Mamy nadzieję, że ta funkcja okaże się przydatna. Prosimy o przekazywanie nam swoich opinii i sugestii dotyczących ulepszeń. Tworzymy TradingView dla Ciebie i zawsze chętnie wysłuchamy Twojego zdania.