JustUncleL

Heiken Ashi zero lag EMA v1.1 by JustUncleL

I originally wrote this script earlier this year for my own use. This released version is an updated version of my original idea based on more recent script ideas. As always with my Alert scripts please do not trade the CALL/PUT indicators blindly, always analyse each position carefully. Always test indicator in DEMO mode first to see if it profitable for your trading style.

DESCRIPTION:
This Alert indicator utilizes the Heiken Ashi with non lag EMA was a scalping and intraday trading system
that has been adapted also for trading with binary options high/low. There is also included
filtering on MACD direction and trend direction as indicated by two MA: smoothed MA(11) and EMA(89).
The the Heiken Ashi candles are great as price action trending indicator, they shows smooth strong
and clear price fluctuations.

Financial Markets: any.
Optimsed settings for 1 min, 5 min and 15 min Time Frame;
Expiry time for Binary options High/Low 3-6 candles.

Indicators used in calculations:
- Exponential moving average , period 89
- Smoothed moving average , period 11
- Non lag EMA, period 20
- MACD 2 colour (13,26,9)


Generate Alerts use the following Trading Rules
Heiken Ashi with non lag dot
Trade only in direction of the trend.
UP trend moving average 11 period is above Exponential moving average 89 period,
Doun trend moving average 11 period is below Exponential moving average 89 period,

CALL Arrow appears when:
Trend UP SMA11>EMA89 (optionally disabled),
Non lag MA blue dot and blue background.
Heike ashi green color.
MACD 2 Colour histogram green bars (optional disabled).

PUT Arrow appears when:
Trend UP SMA11<EMA89 (optionally disabled),
Heike ashi red color.
Non lag MA red dot and red background.
MACD 2 colour histogram red bars (optionally disabled).

HINTS:
- Good positions occur when MACD crosses the Zero line.
- Switch between Heikin Ashi and Normal candles as part of your analysis of the price action.
- Large Heikin Ashi candles with small wicks in direction of trend are good strong trends.
Remove from Favorite Scripts Add to Favorite Scripts
//@version=2
// Title: Heiken Ashi with non lag dot by JustUncleL
// Author: JustUncleL
// Version: 0.2
// Date: 5-feb-2016
//
// Description:
//  This Alert indicator utilizes the Heiken Ashi with non lag EMA was a scalping and intraday trading system
//  that has been adapted also for trading with binary options high/low. There is also included
//  filtering on MACD direction and trend direction as indicated by two MA: smoothed MA(11) and EMA(89).
//  The the Heiken Ashi candles are great as price action trending indicator, they shows smooth strong 
//  and clear price fluctuations.
//  
//  Financial Markets: any.
//  Optimsed settings for 1 min, 5 min and 15 min Time Frame;
//  Expiry time for Binary options High/Low 3-6 candles.
//
//  Indicators used in calculations:
//  - Exponential moving average, period 89
//  - Smoothed moving average, period 11
//  - Non lag EMA, period 20
//  - MACD 2 colour (13,26,9)
//
//
//  Generate Alerts use the following Trading Rules
//    Heiken Ashi with non lag dot
//    Trade only in direction of the trend.
//    UP trend moving average 11 period is above Exponential moving average 89 period,
//    Doun trend moving average 11 period is below Exponential moving average 89 period,
//
//  CALL Arrow appears when:
//    Trend UP SMA11>EMA89 (optionally disabled),
//    Non lag MA blue dot and blue background.
//    Heike ashi green color.
//    MACD 2 Colour histogram green bars (optional disabled).
//
//  PUT Arrow appears when:
//    Trend UP SMA11<EMA89 (optionally disabled),
//    Heike ashi red color.
//    Non lag MA red dot and red background
//    MACD 2 colour histogram red bars (optionally disabled).
// 
// Modifications:
//  0.2 - Added MACD and directional filtering.
//        Added background highlighting of Zero Lag EMA dots.
//        Replaced Bollinger Band squeeze indicator with MACD 2 colour
//  0.1 - Original version.
//
// References:
// - Almost Zero Lag EMA [LazyBear]
// - MACD 2 colour v0.2 by JustUncleL
// - http://www.forexstrategiesresources.com/binary-options-strategies-ii/163-heiken-ashi-with-non-lag-dot/
//
study(title = "Heiken Ashi zero lag EMA v1.1 by JustUncleL", shorttitle="HAZEMA v1.1 by JustUncleL", overlay=true)
//
FastLen = input(11,minval=2,title="Fast Smoothed MA Length")
SlowLen = input(89,minval=10,title="Slow EMA Length")
length=input(20, minval=2,title="Zero Lag EMA (DOTS) Length")
umaf = input(true,title="Use Trend Directional Filter")
//Collect source input and Moving Average Lengths
//
// Use only Heikinashi Candles for all calculations
srcClose = security(heikinashi(tickerid), period, close)
srcOpen =  security(heikinashi(tickerid), period, open)
srcHigh =  security(heikinashi(tickerid), period, high)
srcLow =   security(heikinashi(tickerid), period, low)
//
//
fastMA = input(title="MACD Fast MA Length", type = integer, defval = 13, minval = 2)
slowMA = input(title="MACD Slow MA Length", type = integer, defval = 26, minval = 7)
signal = input(title="MACD Signal Length",  type = integer, defval = 9, minval=1)
umacd  = input(true,title="Use MACD Filtering")
//
[currMacd,currSig,_] = macd(srcClose[0], fastMA, slowMA, signal)
macdH = currMacd > 0 ? rising(currMacd,3) ? green : red : falling(currMacd,3) ? red : green
//
//Calculate No lag EMA
ema1=ema(srcClose, length)
ema2=ema(ema1, length)
d=ema1-ema2
zlema=ema1+d
col =  zlema > zlema[1] ? blue : red
up = zlema > zlema[1] ? true : false
down = zlema < zlema[1] ? true : false
// Draw the DOT no lag MA and colour background to make it easier to see.
plot(zlema,color=col, style=circles, linewidth=4, transp=30, title="HAZEMA ZEMA line")
bgcolor(col, transp=85)

//
// Calculate Smoothed MA and EMA
FastMA = na(FastMA[1]) ? sma(srcClose, FastLen) : (FastMA[1] * (FastLen - 1) + srcClose) / FastLen
SlowMA = ema(srcClose,SlowLen)

// Draw the directional MA's
plot(FastMA,color=olive,transp=0,style=line,linewidth=2)
plot(SlowMA,color=red,transp=0,style=line,linewidth=2)

//
//Calculate potential Entry point
trendup = up and srcOpen<srcClose and (not umaf or FastMA>SlowMA) and (not umacd or macdH==green)? na(trendup[1]) ? 1 : trendup[1]+1 : 0
trenddn = down and srcOpen>srcClose and (not umaf or FastMA<SlowMA) and (not umacd or macdH==red)? na(trenddn[1]) ? 1 : trenddn[1]+1 : 0
//Plot PUT/CALL pointer for entry
plotshape(trenddn==1, title="HAZEMA Up Arrow", style=shape.triangledown,location=location.abovebar, color=red, transp=0, size=size.small,text="PUT")
plotshape(trendup==1,  title="HAZEMA Down Arrow", style=shape.triangleup,location=location.belowbar, color=green, transp=0, size=size.small,text="CALL")

// Create alert to signal entry and plot circle along bottom to indicate alarm set
trendalert = trendup==1 or trenddn==1
alertcondition(trendalert,title="HAZEMA Alert",message="HAZEMA Alert")
plotshape(trendalert[1],  title="HAZEMA Alert Dot", style=shape.circle,location=location.bottom, color=trendup[1]?green:trenddn[1]?red:na, transp=0,offset=-1)

//EOF
hewblot
2 months ago
Hey, how do I add your MACD in addition?
Reply
JustUncleL PRO hewblot
2 months ago
On the the chart just right click mouse button and select "Insert Indicator", then search for "MACD Deuter" written by me and add to chart. Modifiy the "Format" settings to match those used by the "HAZEMA" script.
+1 Reply
Hi JustUncleL there is a MT4 version of your wonderful script?
Reply
JustUncleL PRO salvatore.caligiuri
2 months ago
Yes the script is based on a MT4 idea, check out the "forexstrategiesourses" internet location in the References of my script.
Reply
Ideas Scripts Chart
United States
United Kingdom
India
España
Italia
Brasil
Россия
Türkiye
日本
한국
Home Stock Screener Economic Calendar How It Works Chart Features House Rules Moderators For the WEB Widgets Stock Charting Library Priority Support Feature Request Blog & News FAQ Help & Wiki Twitter
Private Messages Chat Ideas Published Followers Following Priority Support Public Profile Profile Settings Billing Sign Out