ChartArt

Moving Average Cross Alert, Multi-Timeframe (MTF) (by ChartArt)

See when two moving averages cross. With the option to choose between four moving average calculations:


The moving averages can be plotted from different time-frames, like e.g. the weekly or 4 hour time-frame using HL2, HLC3 or OHLC4 as price source for the calculation. In addition there is a background color alert and arrows when the moving averages cross each other when the price also rises or falls. And the moving averages are colored depending on their trend direction (if they are trending up or down).
Remove from Favorite Scripts Add to Favorite Scripts
study("Moving Average Cross Alert, Multi-Timeframe Option (MTF) (by ChartArt)", shorttitle="CA_-_MA_cross", overlay=true)

// ChartArt's Moving Average Cross Indicator
//
// Version 1.0
// Idea by ChartArt on September 15, 2015.
//
// This indicator shows when two moving averages cross.
// With the option to choose between four moving
// average calculations:
// (SMA = simple moving average)
// (EMA = exponential moving average)
// (WMA = weighted moving average)
// (Linear = Linear regression)
//
// The moving averages can be plotted from different
// timeframes, like the weekly or 4 hour timeframe.
// With the possibility to use HL2, HLC3 or OHLC4 prices.
// 
// In addition there is a background color alert
// and arrows when the moving averages cross each other.
// And the moving averages are colored depending if
// they are trending up or down.
//
// List of my work: 
// https://www.tradingview.com/u/ChartArt/


// Multi-timeframe and price input
pricetype = input(close, title="Price Source For The Moving Averages")
useCurrentRes = input(true, title="Use Current Timeframe As Resolution?")
resCustom = input(title="Use Different Timeframe? Then Uncheck The Box Above", type=resolution, defval="W")
res = useCurrentRes ? period : resCustom
price = security(tickerid, res, pricetype)

// MA period input
shortperiod = input(50, title="Short Period Moving Average")
longperiod = input(100, title="Long Period Moving Average")

// MA calculation
smoothinput = input(2, minval=1, maxval=4, title='Moving Average Calculation: (1 = SMA), (2 = EMA), (3 = WMA), (4 = Linear)')
short = smoothinput == 1 ? sma(price, shortperiod) :
    smoothinput == 2 ? ema(price, shortperiod) :
    smoothinput == 3 ? wma(price, shortperiod) :
    smoothinput == 4 ? linreg(price, shortperiod,0) :
    na
long = smoothinput == 1 ? sma(price, longperiod) :
    smoothinput == 2 ? ema(price, longperiod) :
    smoothinput == 3 ? wma(price, longperiod) :
    smoothinput == 4 ? linreg(price, longperiod,0) :
    na

// MA trend direction color
shortcolor = short > short[1] ? lime : short < short[1] ? red : blue
longcolor = long > long[1] ? lime : long < long[1] ? red : blue

// MA output
MA1 = plot(short, title="Short Period Moving Average", style=linebr, linewidth=2, color=shortcolor)
MA2 = plot(long, title="Long Period Moving Average", style=linebr, linewidth=4, color=longcolor)
fill(MA1, MA2, color=silver, transp=50)

// MA trend bar color
TrendingUp() => short > long 
TrendingDown() => short < long 
barcolor(TrendingUp() ? green : TrendingDown() ? red : blue)

// MA cross alert
MAcrossing = cross(short, long) ? short : na
plot(MAcrossing, style = cross, linewidth = 4,color=black)

// MA cross background color alert
Uptrend() => TrendingUp() and TrendingDown()[1]
Downtrend() => TrendingDown() and TrendingUp()[1]
bgcolor(Uptrend() ? green : Downtrend() ? red : na,transp=50)

// Buy and sell alert
Buy = Uptrend() and close > close[1]
Sell = Downtrend() and close < close[1]
plotshape(Buy, color=black, style=shape.arrowup, text="Buy", location=location.bottom)
plotshape(Sell, color=black, style=shape.arrowdown, text="Sell", location=location.top)
Hi! Please can someone tell me how to add an alert for only when a sell or buy signal is generated, would be much appreciated! cheers.
Reply
Hi ChartArt,
very nice script. it is what i have been trying to do in the last two years.
very simple.
i'm new to tradingview, can you explain me how can i use this script?
it is free, right?
how can I customize it an use it?
thanks a lot
A.
Reply
'' - single quote needed aa.mq4 92 50
Meta editor give me error can help me
Reply
I love this script and been using it for a little while but I was wondering how do I make an alert telling me when the buy and sell is?

I added these two lines

alertcondition(Buy, title="Buy BTC Alert")
alertcondition(Sell, title="Sell BTC Alert")

Maybe I'm a bit confused with how to set it up in TradingView's alert system?
Reply
yoda Ddraig
@Ddraig, I would like to set up an alert when 4 time frames indicate a cross 2 with range candles 2 normal is this possible?
+1 Reply
@Ddraig, The function creates alert condition that is available in Create Alert dialog. Please note, that alertcondition does NOT fire alerts from code automatically, it only gives you opportunity to create a custom condition for Create Alert dialog. Alerts must be still set manually. Also, an alert triggered based on a custom condition you created in Pine code is not displayed on a chart.
Reply
I'm very interested in using this for equities swing trading. Is there a way to program a scanner for stocks that meet the specifications?
Reply
tim.turenne coondawg71
I like it for displaying my 3/8 ema cross, to open/reverse following week. KISS!
Reply
@tim.turenne, how can i implement this script to alert me when crossing is ocurring on H4 or H1 timeframe?
Reply
United States
United Kingdom
India
Deutschland
España
France
Việt Nam
Italia
Polska
Brasil
Россия
Türkiye
Indonesia
Malaysia
日本
한국
简体
繁體
Home Stock Screener Forex Signal Finder Cryptocurrency Signal Finder Economic Calendar How It Works Chart Features House Rules Moderators Website & Broker Solutions Widgets Stock Charting Library Feature Request Blog & News FAQ Help & Wiki Twitter
Profile Profile Settings Account and Billing Support Priority Support Report Issue Ideas Published Followers Following Private Messages Chat Sign Out